From ee78a3a3d16565782208b9208a1c5f7858f56eda Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Mon, 3 Jan 2022 18:15:10 -0500
Subject: app-arch/7-zip: upgrade to 21.07, various fixes

---
 app-arch/7-zip/7-zip-21.06.ebuild | 72 ---------------------------------------
 app-arch/7-zip/7-zip-21.07.ebuild | 55 ++++++++++++++++++++++++++++++
 app-arch/7-zip/Manifest           |  2 +-
 3 files changed, 56 insertions(+), 73 deletions(-)
 delete mode 100644 app-arch/7-zip/7-zip-21.06.ebuild
 create mode 100644 app-arch/7-zip/7-zip-21.07.ebuild

(limited to 'app-arch/7-zip')

diff --git a/app-arch/7-zip/7-zip-21.06.ebuild b/app-arch/7-zip/7-zip-21.06.ebuild
deleted file mode 100644
index dfa8c11..0000000
--- a/app-arch/7-zip/7-zip-21.06.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic
-
-MY_PV=${PV%%_*}
-MY_PV=${MY_PV//./}
-
-DESCRIPTION="File archiver with a high compression ratio"
-HOMEPAGE="https://7-zip.org/"
-SRC_URI="https://7-zip.org/a/7z${MY_PV}-src.7z"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="+asm"
-
-BDEPEND="
-	|| ( virtual/7z app-arch/libarchive app-arch/unar )
-	asm? (
-		amd64? ( dev-lang/uasm )
-		arm64? ( dev-lang/uasm )
-		x86? ( dev-lang/uasm )
-	)
-"
-
-S=${WORKDIR}/7z${MY_PV}-src
-
-PATCHES=( ${FILESDIR}/7-zip-flags.patch )
-
-src_unpack() {
-	if command -v 7z >/dev/null 2>&1; then
-		7z x "${DISTDIR}/7z${MY_PV}-src.7z" -o"$S" || die
-	elif command -v bsdtar >/dev/null 2>&1; then
-		mkdir "$S" || die
-		bsdtar -C "$S" -xf "${DISTDIR}/7z${MY_PV}-src.7z" || die
-	elif command -v unar >/dev/null 2>&1; then
-		unar -d "$S" "${DISTDIR}/7z${MY_PV}-src.7z" || die
-	else
-		die "no 7z unpacker found"
-	fi
-}
-
-src_compile() {
-	cd CPP/7zip/Bundles/Alone2 || die
-	local myemakeargs=(
-		CC="$(tc-getCC) ${CFLAGS} ${LDFLAGS}"
-		CXX="$(tc-getCXX) ${CXXFLAGS} ${LDFLAGS}"
-	)
-	if use asm; then
-		myemakeargs+=(USE_ASM=1 MY_ASM=uasm)
-		if use amd64; then
-			myemakeargs+=(IS_X64=1)
-		elif use arm64; then
-			myemakeargs+=(IS_ARM64=1)
-		elif use x86; then
-			myemakeargs+=(IS_X86=1)
-		else
-			einfo "asm is not supported on this arch, ignoring"
-		fi
-	fi
-	mkdir -p b/g || die
-	emake -f ../../cmpl_gcc.mak "${myemakeargs[@]}"
-}
-
-src_install() {
-	dobin CPP/7zip/Bundles/Alone2/b/g/7zz
-	dosym 7zz /usr/bin/7z
-	dodoc DOC/*
-}
diff --git a/app-arch/7-zip/7-zip-21.07.ebuild b/app-arch/7-zip/7-zip-21.07.ebuild
new file mode 100644
index 0000000..86d7287
--- /dev/null
+++ b/app-arch/7-zip/7-zip-21.07.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+MY_PV=${PV%%_*}
+MY_PV=${MY_PV//./}
+
+DESCRIPTION="File archiver with a high compression ratio"
+HOMEPAGE="https://7-zip.org/"
+SRC_URI="https://7-zip.org/a/7z${MY_PV}-src.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+asm"
+
+BDEPEND="
+	asm? ( dev-lang/jwasm )
+"
+RDEPEND="!app-arch/p7zip"
+
+S=${WORKDIR}
+
+PATCHES=( ${FILESDIR}/7-zip-flags.patch )
+
+src_compile() {
+	cd CPP/7zip/Bundles/Alone2 || die
+	local myemakeargs=(
+		CC="$(tc-getCC) ${CFLAGS} ${LDFLAGS}"
+		CXX="$(tc-getCXX) ${CXXFLAGS} ${LDFLAGS}"
+	)
+	if use asm; then
+		myemakeargs+=(USE_ASM=1 USE_JWASM=1)
+		if use amd64; then
+			myemakeargs+=(IS_X64=1)
+		elif use arm64; then
+			myemakeargs+=(IS_ARM64=1)
+		elif use x86; then
+			myemakeargs+=(IS_X86=1)
+		else
+			einfo "asm is not supported on this arch, ignoring"
+		fi
+	fi
+	mkdir -p b/g || die
+	emake -f ../../cmpl_gcc.mak "${myemakeargs[@]}"
+}
+
+src_install() {
+	dobin CPP/7zip/Bundles/Alone2/b/g/7zz
+	dosym 7zz /usr/bin/7z
+	dodoc DOC/*
+}
diff --git a/app-arch/7-zip/Manifest b/app-arch/7-zip/Manifest
index eb7491c..1dc3b00 100644
--- a/app-arch/7-zip/Manifest
+++ b/app-arch/7-zip/Manifest
@@ -1 +1 @@
-DIST 7z2106-src.7z 1215031 BLAKE2B c66d29224e3cab210a9d575b1954d63499cf0eea7c04a5fa339498aca292aa6b2198024de380c25a16c88953fdae2e94ed9760350464f808b3d69dfbdae5aea8 SHA512 2ad05eaf14770584d7e6111734c7c239ab0163f9fd9b0cc5473fa33d5c882b0493331dd0f851af5e8be2b7d1eaede2f96f30f8e777b05d17c46a0121ff8211ec
+DIST 7z2107-src.tar.xz 1230388 BLAKE2B 59e460cdf5a0d78669decee2578a1f7ad398de66e99eb556f9af574b2a7957d1e67b949e240af56c7cbdbaca8d35c6a9256f4153b71de170590e13c47f314510 SHA512 c964e3f1193adb72adc338416ab3226ee2655b9a953f0ec7dafc83adafdfa6b89e32752bd23d521086d96164fca1795064f888e0c37b13e7160fdb37e61d2018
-- 
cgit v1.2.3-70-g09d2