From b1c96b13cceae97a4f5cae7de7c2f9157d3fe8b6 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Mon, 31 May 2021 08:05:46 -0400
Subject: app-text/evince: sync
---
app-text/evince/Manifest | 1 -
app-text/evince/evince-3.36.10-r1.ebuild | 104 -------------------------
app-text/evince/evince-40.0-r1.ebuild | 129 -------------------------------
app-text/evince/evince-40.0-r2.ebuild | 127 ++++++++++++++++++++++++++++++
4 files changed, 127 insertions(+), 234 deletions(-)
delete mode 100644 app-text/evince/evince-3.36.10-r1.ebuild
delete mode 100644 app-text/evince/evince-40.0-r1.ebuild
create mode 100644 app-text/evince/evince-40.0-r2.ebuild
(limited to 'app-text/evince')
diff --git a/app-text/evince/Manifest b/app-text/evince/Manifest
index 595f68e..a023f30 100644
--- a/app-text/evince/Manifest
+++ b/app-text/evince/Manifest
@@ -1,2 +1 @@
-DIST evince-3.36.10.tar.xz 2430584 BLAKE2B 7c8b5e3dec7168f4ab6976022bb85041fd8cc9f55b8c032bbf03cf492d243dc49f00d6913c1f2f09498c1b4091b4be126a9367dd3ed235635e9d08e6a9ae5a0d SHA512 2a17fc1fbd18e2685c254194d0e195ec0c6126f37212ae64297fb06f30f2e07f926cb768affb4d5c9c407c4dfc43db3578ffd244c9a6e121d1d3c9b5e653b4d2
DIST evince-40.0.tar.xz 2928668 BLAKE2B 852c532b595f50e849893670b536b5b8c25f0407a719cbe659faa3f72b51f43a0471c3df9197fa5bd11735c14e0779d8cf28a88cd79aabec4dffa797443b9819 SHA512 995693e4a6e1a3bb31e1d4f3538dc53519102a5a6afa58ba61454a1e2ca582df26bd368876210fce6fab8ff4e218305644fa7a7a88c99e1a1ca5bda8d8f1ece2
diff --git a/app-text/evince/evince-3.36.10-r1.ebuild b/app-text/evince/evince-3.36.10-r1.ebuild
deleted file mode 100644
index ecd279e..0000000
--- a/app-text/evince/evince-3.36.10-r1.ebuild
+++ /dev/null
@@ -1,104 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-GNOME2_EAUTORECONF="yes"
-
-inherit gnome2 systemd
-
-DESCRIPTION="Simple document viewer for GNOME"
-HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
-
-LICENSE="GPL-2+ CC-BY-SA-3.0"
-# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
-SLOT="0/evd3.4-evv3.3"
-IUSE="djvu dvi gstreamer gnome gnome-keyring +introspection nautilus nsplugin postscript spell t1lib tiff xps"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
-
-# atk used in libview
-# bundles unarr
-DEPEND="
- dev-libs/atk
- >=dev-libs/glib-2.38.0:2
- >=dev-libs/libxml2-2.5:2
- sys-libs/zlib:=
- >=x11-libs/gdk-pixbuf-2.36.5:2
- >=x11-libs/gtk+-3.22.0:3[introspection?]
- gnome-base/gsettings-desktop-schemas
- >=x11-libs/cairo-1.10:=
- >=app-text/poppler-0.76.0[cairo]
- >=app-arch/libarchive-3.2.0
- djvu? ( >=app-text/djvu-3.5.22:= )
- dvi? (
- virtual/tex-base
- dev-libs/kpathsea:=
- t1lib? ( >=media-libs/t1lib-5:= ) )
- gstreamer? (
- media-libs/gstreamer:1.0
- media-libs/gst-plugins-base:1.0
- media-libs/gst-plugins-good:1.0 )
- gnome? ( gnome-base/gnome-desktop:3= )
- gnome-keyring? ( >=app-crypt/libsecret-0.5 )
- introspection? ( >=dev-libs/gobject-introspection-1:= )
- nautilus? ( >=gnome-base/nautilus-3.28.0 )
- postscript? ( >=app-text/libspectre-0.2:= )
- spell? ( >=app-text/gspell-1.6.0:= )
- tiff? ( >=media-libs/tiff-3.6:0= )
- xps? ( >=app-text/libgxps-0.2.1:= )
-"
-RDEPEND="${DEPEND}
- || (
- >=x11-themes/adwaita-icon-theme-2.17.1
- >=x11-themes/hicolor-icon-theme-0.10 )
-"
-BDEPEND="
- app-text/docbook-xml-dtd:4.3
- dev-libs/appstream-glib
- dev-util/gdbus-codegen
- dev-util/glib-utils
- >=dev-util/gtk-doc-am-1.13
- dev-util/itstool
- >=sys-devel/gettext-0.19.8
- virtual/pkgconfig
- app-text/yelp-tools
-"
-# eautoreconf needs:
-# app-text/yelp-tools
-
-PATCHES=(
- "${FILESDIR}"/3.30.2-internal-synctex.patch # don't automagically link to synctex from texlive-core - always use internal copy of this small parser for now; requires eautoreconf
-)
-
-src_prepare() {
- gnome2_src_prepare
-
- # Do not depend on adwaita-icon-theme, bug #326855, #391859
- # https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
- sed -e 's/adwaita-icon-theme >= $ADWAITA_ICON_THEME_REQUIRED//g' \
- -i configure || die "sed failed"
-}
-
-src_configure() {
- gnome2_src_configure \
- --disable-static \
- --enable-pdf \
- --enable-comics \
- --enable-thumbnailer \
- --with-platform=gnome \
- --enable-dbus \
- $(use_enable djvu) \
- $(use_enable dvi) \
- $(use_enable gstreamer multimedia) \
- $(use_enable gnome libgnome-desktop) \
- $(use_with gnome-keyring keyring) \
- $(use_enable introspection) \
- $(use_enable nautilus) \
- $(use_enable nsplugin browser-plugin) \
- $(use_enable postscript ps) \
- $(use_with spell gspell) \
- $(use_enable t1lib) \
- $(use_enable tiff) \
- $(use_enable xps) \
- BROWSER_PLUGIN_DIR="${EPREFIX}"/usr/$(get_libdir)/nsbrowser/plugins \
- --with-systemduserunitdir="$(systemd_get_userunitdir)"
-}
diff --git a/app-text/evince/evince-40.0-r1.ebuild b/app-text/evince/evince-40.0-r1.ebuild
deleted file mode 100644
index 21dda55..0000000
--- a/app-text/evince/evince-40.0-r1.ebuild
+++ /dev/null
@@ -1,129 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit gnome.org meson systemd
-
-DESCRIPTION="Simple document viewer for GNOME"
-HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
-
-LICENSE="GPL-2+ CC-BY-SA-3.0"
-# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
-SLOT="0/evd3.4-evv3.3"
-IUSE="cups djvu dvi gstreamer gnome gnome-keyring gtk-doc +introspection nautilus nsplugin postscript spell t1lib tiff xps"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
-
-# atk used in libview
-# bundles unarr
-DEPEND="
- dev-libs/atk
- >=dev-libs/glib-2.44.0:2
- >=gui-libs/libhandy-1.0:1=
- >=dev-libs/libxml2-2.5:2
- sys-libs/zlib:=
- >=x11-libs/gdk-pixbuf-2.40:2
- >=x11-libs/gtk+-3.22.0:3[cups?,introspection?]
- gnome-base/gsettings-desktop-schemas
- >=x11-libs/cairo-1.10:=
- >=app-text/poppler-0.76.0[cairo]
- >=app-arch/libarchive-3.2.0
- djvu? ( >=app-text/djvu-3.5.22:= )
- dvi? (
- >=app-text/libspectre-0.2:=
- dev-libs/kpathsea:=
- t1lib? ( >=media-libs/t1lib-5:= ) )
- gstreamer? (
- media-libs/gstreamer:1.0
- media-libs/gst-plugins-base:1.0
- media-libs/gst-plugins-good:1.0 )
- gnome? ( gnome-base/gnome-desktop:3= )
- gnome-keyring? ( >=app-crypt/libsecret-0.5 )
- introspection? ( >=dev-libs/gobject-introspection-1:= )
- nautilus? ( >=gnome-base/nautilus-3.28.0 )
- postscript? ( >=app-text/libspectre-0.2:= )
- spell? ( >=app-text/gspell-1.6.0:= )
- tiff? ( >=media-libs/tiff-3.6:0= )
- xps? ( >=app-text/libgxps-0.2.1:= )
-"
-RDEPEND="${DEPEND}
- || (
- >=x11-themes/adwaita-icon-theme-2.17.1
- >=x11-themes/hicolor-icon-theme-0.10
- )
-"
-BDEPEND="
- gtk-doc? ( >=dev-util/gtk-doc-1.33 )
- app-text/docbook-xml-dtd:4.3
- dev-libs/appstream-glib
- dev-util/gdbus-codegen
- dev-util/glib-utils
- dev-util/itstool
- >=sys-devel/gettext-0.19.8
- virtual/pkgconfig
-"
-
-PATCHES=(
- "${FILESDIR}"/40.0-internal-synctex.patch
- "${FILESDIR}"/40.0-avoid-changing-soname.patch
-)
-
-src_prepare() {
- default
-
- # Do not depend on adwaita-icon-theme, bug #326855, #391859
- # https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
- sed -i '/adwaita_icon_theme_dep/d' meson.build shell/meson.build || die
-
- # https://gitlab.gnome.org/GNOME/evince/-/merge_requests/336
- sed -i -e 's:T1_initLib:T1_InitLib:' meson.build || die
-}
-
-src_configure() {
- local emesonargs=(
- -Dplatform=gnome
-
- -Dviewer=true
- -Dpreviewer=false
- -Dthumbnailer=true
- $(meson_use nsplugin browser_plugin)
- $(meson_use nautilus)
-
- -Dcomics=enabled
- $(meson_feature djvu)
- $(meson_feature dvi)
- -Dpdf=enabled
- $(meson_feature postscript ps)
- $(meson_feature tiff)
- $(meson_feature xps)
-
- $(meson_use gtk-doc gtk_doc)
- -Duser_doc=true
- $(meson_use introspection)
- -Ddbus=true
- $(meson_feature gnome-keyring keyring)
- $(meson_feature cups gtk_unix_print)
- $(meson_feature gnome thumbnail_cache)
- $(meson_feature gstreamer multimedia)
- $(meson_feature spell gspell)
-
- $(meson_feature t1lib)
-
- -Dbrowser_plugin_dir="${EPREFIX}/usr/$(get_libdir)/nsbrowser/plugins"
- -Dsystemduserunitdir="$(systemd_get_userunitdir)"
-
- )
- meson_src_configure
-}
-
-src_compile() {
- meson_src_compile
-}
-
-src_test() {
- meson_src_test
-}
-
-src_install() {
- meson_src_install
-}
diff --git a/app-text/evince/evince-40.0-r2.ebuild b/app-text/evince/evince-40.0-r2.ebuild
new file mode 100644
index 0000000..ba0e425
--- /dev/null
+++ b/app-text/evince/evince-40.0-r2.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson systemd xdg
+
+DESCRIPTION="Simple document viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
+SLOT="0/evd3.4-evv3.3"
+IUSE="cups djvu dvi gstreamer gnome gnome-keyring gtk-doc +introspection nautilus nsplugin postscript spell t1lib tiff xps"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+# atk used in libview
+# bundles unarr
+DEPEND="
+ dev-libs/atk
+ >=dev-libs/glib-2.44.0:2
+ >=gui-libs/libhandy-1.0:1=
+ >=dev-libs/libxml2-2.5:2
+ sys-libs/zlib:=
+ >=x11-libs/gdk-pixbuf-2.40:2
+ >=x11-libs/gtk+-3.22.0:3[cups?,introspection?]
+ gnome-base/gsettings-desktop-schemas
+ >=x11-libs/cairo-1.10:=
+ >=app-text/poppler-0.76.0[cairo]
+ >=app-arch/libarchive-3.2.0
+ djvu? ( >=app-text/djvu-3.5.22:= )
+ dvi? (
+ >=app-text/libspectre-0.2:=
+ dev-libs/kpathsea:=
+ t1lib? ( >=media-libs/t1lib-5:= ) )
+ gstreamer? (
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ media-libs/gst-plugins-good:1.0 )
+ gnome? ( gnome-base/gnome-desktop:3= )
+ gnome-keyring? ( >=app-crypt/libsecret-0.5 )
+ introspection? ( >=dev-libs/gobject-introspection-1:= )
+ nautilus? ( >=gnome-base/nautilus-3.28.0 )
+ postscript? ( >=app-text/libspectre-0.2:= )
+ spell? ( >=app-text/gspell-1.6.0:= )
+ tiff? ( >=media-libs/tiff-3.6:0= )
+ xps? ( >=app-text/libgxps-0.2.1:= )
+"
+RDEPEND="${DEPEND}
+ || (
+ >=x11-themes/adwaita-icon-theme-2.17.1
+ >=x11-themes/hicolor-icon-theme-0.10
+ )
+"
+BDEPEND="
+ gtk-doc? ( >=dev-util/gtk-doc-1.33 )
+ app-text/docbook-xml-dtd:4.3
+ dev-libs/appstream-glib
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/itstool
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PV}-build-Fix-t1lib-detection.patch
+ "${FILESDIR}"/${PV}-previewer-Fix-build-regression-when-gtk_unix_print-i.patch
+ "${FILESDIR}"/40.0-internal-synctex.patch
+)
+
+src_prepare() {
+ default
+
+ # Do not depend on adwaita-icon-theme, bug #326855, #391859
+ # https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
+ sed -i '/adwaita_icon_theme_dep/d' meson.build shell/meson.build || die
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dplatform=gnome
+
+ -Dviewer=true
+ -Dpreviewer=true
+ -Dthumbnailer=true
+ $(meson_use nsplugin browser_plugin)
+ $(meson_use nautilus)
+
+ -Dcomics=enabled
+ $(meson_feature djvu)
+ $(meson_feature dvi)
+ -Dpdf=enabled
+ $(meson_feature postscript ps)
+ $(meson_feature tiff)
+ $(meson_feature xps)
+
+ $(meson_use gtk-doc gtk_doc)
+ -Duser_doc=true
+ $(meson_use introspection)
+ -Ddbus=true
+ $(meson_feature gnome-keyring keyring)
+ $(meson_feature cups gtk_unix_print)
+ $(meson_feature gnome thumbnail_cache)
+ $(meson_feature gstreamer multimedia)
+ $(meson_feature spell gspell)
+
+ $(meson_feature t1lib)
+
+ -Dbrowser_plugin_dir="${EPREFIX}/usr/$(get_libdir)/nsbrowser/plugins"
+ -Dsystemduserunitdir="$(systemd_get_userunitdir)"
+
+ )
+ meson_src_configure
+}
+
+src_compile() {
+ meson_src_compile
+}
+
+src_test() {
+ meson_src_test
+}
+
+src_install() {
+ meson_src_install
+}
--
cgit v1.2.3-70-g09d2