From 8e2d45dcc43c36540a9841c4b6826ecc0d826fc5 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Mon, 28 Feb 2022 17:57:21 -0500
Subject: dev-dotnet/dotnet-runtime-bin: new package

---
 .../dotnet-runtime-bin-3.1.22.ebuild               | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-3.1.22.ebuild

(limited to 'dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-3.1.22.ebuild')

diff --git a/dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-3.1.22.ebuild b/dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-3.1.22.ebuild
new file mode 100644
index 0000000..12d4b2a
--- /dev/null
+++ b/dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-3.1.22.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/"
+LICENSE="MIT"
+
+SRC_URI="
+amd64? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-x64.tar.gz )
+arm? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-arm.tar.gz )
+arm64? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-arm64.tar.gz )
+"
+
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64"
+IUSE="dotnet-symlink kerberos lttng"
+REQUIRED_USE="elibc_glibc"
+QA_PREBUILT="*"
+RESTRICT="splitdebug"
+RDEPEND="
+	kerberos? ( app-crypt/mit-krb5:0/0 )
+	lttng? ( dev-util/lttng-ust:0 )
+	sys-libs/zlib:0/1
+	dotnet-symlink? (
+		!dev-dotnet/dotnet-sdk[dotnet-symlink(+)]
+		!dev-dotnet/dotnet-sdk-bin[dotnet-symlink(+)]
+		!dev-dotnet/dotnet-runtime[dotnet-symlink(+)]
+	)
+"
+
+S=${WORKDIR}
+
+delete() {
+	local x
+	x=$(find . -name "$1" -print -delete) && [ -n "$x" ]
+}
+
+src_compile() {
+	use kerberos || delete System.Net.Security.Native.so || die
+	use lttng || delete libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	local dest="opt/${PN}-${SLOT}"
+	dodir "${dest%/*}"
+
+	{ mv "${S}" "${ED}/${dest}" && mkdir "${S}" && fperms 0755 "/${dest}"; } || die
+	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SLOT}"
+
+	if use dotnet-symlink; then
+		dosym "../../${dest}/dotnet" "/usr/bin/dotnet"
+		dosym "../../${dest}/dotnet" "/usr/bin/dotnet-${SLOT}"
+
+		# set an env-variable for 3rd party tools
+		echo "DOTNET_ROOT=/${dest}" > "${T}/90${PN}-${SLOT}" || die
+		doenvd "${T}/90${PN}-${SLOT}"
+	fi
+}
-- 
cgit v1.2.3-54-g00ecf