From b11fc4daad7a559f97677f2e3f21f3cafcedcb62 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Wed, 8 Jan 2025 12:05:25 -0500
Subject: dev-dotnet/dotnet-runtime-bin: update to 9.0.0

---
 .../dotnet-runtime-bin-8.0.11.ebuild               | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-8.0.11.ebuild

(limited to 'dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-8.0.11.ebuild')

diff --git a/dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-8.0.11.ebuild b/dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-8.0.11.ebuild
new file mode 100644
index 0000000..b3e3224
--- /dev/null
+++ b/dev-dotnet/dotnet-runtime-bin/dotnet-runtime-bin-8.0.11.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/"
+
+gen_src_uri() {
+	echo "$1? (
+		elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-${2:-$1}.tar.gz )
+		elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-musl-${2:-$1}.tar.gz )
+	)"
+}
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="-* ~amd64 ~arm ~arm64"
+IUSE="lttng"
+
+SRC_URI="
+	$(gen_src_uri amd64 x64)
+	$(gen_src_uri arm)
+	$(gen_src_uri arm64)
+"
+
+RDEPEND="
+	sys-libs/zlib:0/1
+	!dev-dotnet/dotnet-sdk-bin:${SLOT}
+	lttng? ( =dev-util/lttng-ust-2.12* )
+"
+IDEPEND="
+	app-eselect/eselect-dotnet
+"
+
+S=${WORKDIR}
+
+QA_PREBUILT="*"
+RESTRICT+=" splitdebug"
+
+delete() {
+	test -n "$(find . -name "$1" -print -delete)"
+}
+
+src_compile() {
+	use lttng || delete libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	local dest="opt/${PN}-${SLOT}"
+	dodir "${dest%/*}"
+
+	mv "${S}" "${ED}/${dest}" || die
+	mkdir "${S}" || die
+	fperms 0755 "/${dest}"
+
+	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SLOT}"
+}
+
+pkg_postinst() {
+	eselect dotnet update ifunset
+}
+
+pkg_postrm() {
+	eselect dotnet update ifunset
+}
-- 
cgit v1.2.3-70-g09d2