From 968122b6356dff143231c5aedfc2ca24728c7e12 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Tue, 1 Oct 2024 15:11:30 -0400
Subject: dev-java/openj9-openjdk*: upgrade to 0.46.1

---
 .../openj9-openjdk-jre-bin-17.0.9_p9.ebuild        | 85 ----------------------
 1 file changed, 85 deletions(-)
 delete mode 100644 dev-java/openj9-openjdk-jre-bin/openj9-openjdk-jre-bin-17.0.9_p9.ebuild

(limited to 'dev-java/openj9-openjdk-jre-bin/openj9-openjdk-jre-bin-17.0.9_p9.ebuild')

diff --git a/dev-java/openj9-openjdk-jre-bin/openj9-openjdk-jre-bin-17.0.9_p9.ebuild b/dev-java/openj9-openjdk-jre-bin/openj9-openjdk-jre-bin-17.0.9_p9.ebuild
deleted file mode 100644
index 7aa42d8..0000000
--- a/dev-java/openj9-openjdk-jre-bin/openj9-openjdk-jre-bin-17.0.9_p9.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit java-vm-2
-
-abi_uri() {
-	echo "${2-$1}? (
-		https://github.com/ibmruntimes/semeru${SLOT}-binaries/releases/download/jdk-${DL_PV/+/%2B}/ibm-semeru-open-jre_${1}_linux_${DL_PV/+/_}.tar.gz
-	)"
-}
-
-JDK_PV=${PV//_p/+}
-DL_PV=${JDK_PV}_openj9-0.41.0
-SLOT=$(ver_cut 1)
-
-SRC_URI="
-	$(abi_uri aarch64 arm64)
-	$(abi_uri ppc64le ppc64)
-	$(abi_uri x64 amd64)
-"
-
-DESCRIPTION="Prebuilt IBM Semeru JRE binaries provided by IBM"
-HOMEPAGE="https://developer.ibm.com/languages/java/semeru-runtimes/"
-LICENSE="GPL-2-with-classpath-exception"
-KEYWORDS="~amd64 ~arm64 ~ppc64"
-IUSE="alsa cups headless-awt selinux"
-
-RDEPEND="
-	media-libs/fontconfig:1.0
-	media-libs/freetype:2
-	>=sys-apps/baselayout-java-0.1.0-r1
-	>=sys-libs/glibc-2.2.5:*
-	sys-libs/zlib
-	alsa? ( media-libs/alsa-lib )
-	cups? ( net-print/cups )
-	selinux? ( sec-policy/selinux-java )
-	!headless-awt? (
-		x11-libs/libX11
-		x11-libs/libXext
-		x11-libs/libXi
-		x11-libs/libXrender
-		x11-libs/libXtst
-	)"
-
-RESTRICT="preserve-libs splitdebug"
-QA_PREBUILT="*"
-
-S="${WORKDIR}/jdk-${JDK_PV}-jre"
-
-src_install() {
-	local dest="/opt/${PN}-${SLOT}"
-	local ddest="${ED}/${dest#/}"
-
-	# Not sure why they bundle this as it's commonly available and they
-	# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
-	# also has an explicit dependency while Oracle seemingly dlopens it.
-	rm -vf lib/libfreetype.so || die
-
-	# Oracle and IcedTea have libjsoundalsa.so depending on
-	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
-	if ! use alsa ; then
-		rm -v lib/libjsound.* || die
-	fi
-
-	if use headless-awt ; then
-		rm -v lib/lib*{[jx]awt,splashscreen}* || die
-	fi
-
-	rm -v lib/security/cacerts || die
-	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
-
-	dodir "${dest}"
-	cp -pPR * "${ddest}" || die
-
-	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
-	java-vm_set-pax-markings "${ddest}"
-	java-vm_revdep-mask
-	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
-}
-
-pkg_postinst() {
-	java-vm-2_pkg_postinst
-}
-- 
cgit v1.2.3-70-g09d2