From 75ad83d8b5c2eaa773be929d89d21d7b75786fd0 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Fri, 11 Dec 2020 16:36:31 -0500
Subject: dev-python/fonttools: bump to 4.18.1

---
 dev-python/fonttools/fonttools-4.18.1.ebuild | 50 ++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/fonttools/fonttools-4.18.1.ebuild

(limited to 'dev-python/fonttools/fonttools-4.18.1.ebuild')

diff --git a/dev-python/fonttools/fonttools-4.18.1.ebuild b/dev-python/fonttools/fonttools-4.18.1.ebuild
new file mode 100644
index 0000000..34950d6
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.18.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_6,3_7,3_8,3_9} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="https://github.com/fonttools/fonttools/"
+SRC_URI="https://github.com/fonttools/fonttools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+RESTRICT="!test? ( test )"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+
+		>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)"
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx pytest -vv Tests fontTools
+}
-- 
cgit v1.2.3-70-g09d2