From 947e0b5f512c56edc1b2b414bc86b6298d068cde Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Sun, 25 Oct 2020 20:51:14 -0400
Subject: treewide: updates

---
 gui-apps/waypipe/waypipe-0.7.0.ebuild | 50 +++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 gui-apps/waypipe/waypipe-0.7.0.ebuild

(limited to 'gui-apps/waypipe/waypipe-0.7.0.ebuild')

diff --git a/gui-apps/waypipe/waypipe-0.7.0.ebuild b/gui-apps/waypipe/waypipe-0.7.0.ebuild
new file mode 100644
index 0000000..8694eca
--- /dev/null
+++ b/gui-apps/waypipe/waypipe-0.7.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="proxy for Wayland clients"
+HOMEPAGE="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+SRC_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe/-/archive/v${PV}/waypipe-v${PV}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+drm ffmpeg lz4 +man test vaapi zstd"
+
+REQUIRED_USE="vaapi? ( ffmpeg )"
+
+DEPEND="
+	dev-libs/wayland
+	drm? ( x11-libs/libdrm )
+	ffmpeg? ( media-video/ffmpeg )
+	lz4? ( app-arch/lz4:= )
+	vaapi? ( x11-libs/libva )
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/wayland-protocols
+	man? ( app-text/scdoc )
+	test? ( dev-libs/weston )
+"
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_configure() {
+	local emesonargs=(
+		-Dwerror=false
+		$(meson_feature man man-pages)
+		$(meson_feature ffmpeg with_video)
+		$(meson_feature drm with_dmabuf)
+		$(meson_feature lz4 with_lz4)
+		$(meson_feature zstd with_zstd)
+		$(meson_feature vaapi with_vaapi)
+	)
+	meson_src_configure
+}
-- 
cgit v1.2.3-54-g00ecf