From 4b577c393cc6d5f058cc0c3061591b67e2ee0e30 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Mon, 17 Aug 2020 20:24:31 -0400
Subject: gui-apps/gammastep: import from sorrow

---
 gui-apps/gammastep/Manifest               |  1 +
 gui-apps/gammastep/files/metainfo.patch   | 11 ++++
 gui-apps/gammastep/gammastep-2.0.1.ebuild | 85 +++++++++++++++++++++++++++++++
 3 files changed, 97 insertions(+)
 create mode 100644 gui-apps/gammastep/Manifest
 create mode 100644 gui-apps/gammastep/files/metainfo.patch
 create mode 100644 gui-apps/gammastep/gammastep-2.0.1.ebuild

(limited to 'gui-apps')

diff --git a/gui-apps/gammastep/Manifest b/gui-apps/gammastep/Manifest
new file mode 100644
index 0000000..0128247
--- /dev/null
+++ b/gui-apps/gammastep/Manifest
@@ -0,0 +1 @@
+DIST gammastep-2.0.1.tar.bz2 528979 BLAKE2B ff46e56d91b89c191f5a01c8187ecd3e97b46fb79b9db4b981e3eb7918709cf5cd776d6088bacf0caaf6e6426022df26f49cf7290d221fc4f51ca1b80e9a004e SHA512 db832e047eb55a455b95ad0db3d0fc61185619237182414f9985d92eaa976986068b6dbac09769a2f93799ac0eb32901e0c27ed12926153ec66297b457afc2af
diff --git a/gui-apps/gammastep/files/metainfo.patch b/gui-apps/gammastep/files/metainfo.patch
new file mode 100644
index 0000000..6cc487b
--- /dev/null
+++ b/gui-apps/gammastep/files/metainfo.patch
@@ -0,0 +1,11 @@
+--- a/Makefile.am	2020-07-19 20:09:44.929367324 +1000
++++ b/Makefile.am	2020-07-19 20:10:10.274780215 +1000
+@@ -80,7 +80,7 @@
+ 
+ # Appdata file
+ if ENABLE_GUI
+-appdatadir = @datadir@/appdata
++appdatadir = @datadir@/metainfo
+ appdata_DATA = $(APPDATA_IN_FILES:.xml.in=.xml)
+ 
+ # We would preferable use @INTLTOOL_XML_RULE@ here but
diff --git a/gui-apps/gammastep/gammastep-2.0.1.ebuild b/gui-apps/gammastep/gammastep-2.0.1.ebuild
new file mode 100644
index 0000000..98c0ba4
--- /dev/null
+++ b/gui-apps/gammastep/gammastep-2.0.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit systemd autotools gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="https://gitlab.com/chinstrap/gammastep/"
+SRC_URI="https://gitlab.com/chinstrap/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="appindicator geoclue gtk nls wayland"
+
+BDEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )
+	wayland? ( >=dev-libs/wayland-1.15.0 )"
+RDEPEND="${DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}/metainfo.patch"
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		$(use_enable geoclue geoclue2) \
+		$(use_enable gtk gui) \
+		$(use_enable wayland) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--enable-apparmor
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/gammastep_indicator install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/gammastep-indicator
+
+		python_foreach_impl python_optimize
+	fi
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}
-- 
cgit v1.2.3-54-g00ecf