From d241ee7943383a8ad8aacd70d5e301a6acf22c38 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Tue, 28 Jul 2020 09:41:37 -0400
Subject: Initial commit

---
 mail-client/astroid/astroid-9999.ebuild | 91 +++++++++++++++++++++++++++++++++
 mail-client/astroid/metadata.xml        | 23 +++++++++
 2 files changed, 114 insertions(+)
 create mode 100644 mail-client/astroid/astroid-9999.ebuild
 create mode 100644 mail-client/astroid/metadata.xml

(limited to 'mail-client/astroid')

diff --git a/mail-client/astroid/astroid-9999.ebuild b/mail-client/astroid/astroid-9999.ebuild
new file mode 100644
index 0000000..f79f8e9
--- /dev/null
+++ b/mail-client/astroid/astroid-9999.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+: "${CMAKE_MAKEFILE_GENERATOR:=ninja}"
+
+inherit cmake git-r3 virtualx
+
+DESCRIPTION="lightweight graphical threads-with-tags style email client for notmuch"
+HOMEPAGE="https://github.com/astroidmail/astroid"
+EGIT_REPO_URI="https://github.com/astroidmail/astroid.git"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS=""
+IUSE="+doc embedded-editor plugins profile terminal test"
+
+RDEPEND="
+	plugins? (
+		dev-libs/gobject-introspection
+		>=dev-libs/libpeas-1.0.0
+		|| (
+			dev-libs/gmime:3.0[vala]
+			dev-libs/gmime:2.6[vala]
+		)
+	)
+	terminal? (
+		x11-libs/vte:2.91
+	)
+	|| (
+		>=dev-libs/gmime-3.0.3:3.0
+		>=dev-libs/gmime-2.6.21:2.6
+	)
+	dev-cpp/glibmm:2
+	>=dev-cpp/gtkmm-3.10:3.0[X]
+	dev-libs/boost[nls]
+	dev-libs/libsass
+	>=dev-libs/protobuf-3.6.0:=
+	net-libs/libsoup:2.4
+	>=net-libs/webkit-gtk-2.22.0:4
+	net-mail/notmuch
+"
+DEPEND="${RDEPEND}
+	doc? (
+		|| (
+			app-text/scdoc
+			app-text/ronn
+		)
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		app-crypt/gnupg
+		app-text/cmark
+	)
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	if ! use test; then
+		sed -i -e '/enable_testing/d;/add_subdirectory.*tests.*/d' CMakeLists.txt
+		rm -rf tests
+	fi
+
+	if use terminal; then
+		sed -i -e '/pkg_check_modules.*VTE2/s/VTE2/VTE2 REQUIRED/' CMakeLists.txt
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_DOCS=$(usex doc OFF ON)
+		-DDISABLE_EMBEDDED_EDITOR=$(usex embedded-editor OFF ON)
+		-DDISABLE_TERMINAL=$(usex terminal OFF ON)
+		-DDISABLE_PLUGINS=$(usex plugins OFF ON)
+		-DENABLE_PROFILING=$(usex profile ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+pkg_postinst() {
+	optfeature "GnuPG" app-crypt/gnupg
+	optfeature "Markdown" app-text/cmark
+}
diff --git a/mail-client/astroid/metadata.xml b/mail-client/astroid/metadata.xml
new file mode 100644
index 0000000..cb93a79
--- /dev/null
+++ b/mail-client/astroid/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<upstream>
+<remote-id type="github">astroidmail/astroid</remote-id>
+</upstream>
+<maintainer type="person">
+<email>alex_y_xu@yahoo.ca</email>
+<name>Alex Xu (Hello71)</name>
+</maintainer>
+<maintainer type="project">
+<email>proxy-maint@gentoo.org</email>
+<name>Proxy Maintainers</name>
+</maintainer>
+<longdescription lang="en">
+Astroid is a lightweight and fast Mail User Agent that provides a graphical interface to searching, displaying and composing email, organized in threads and tags. Astroid uses the notmuch backend for blazingly fast searches through tons of email. Astroid searches, displays and composes emails - and rely on other programs for fetching, syncing and sending email.
+</longdescription>
+<use>
+<flag name="embedded-editor">Embedded editor</flag>
+<flag name="plugins">Plugins</flag>
+<flag name="terminal">Embedded terminal</flag>
+</use>
+</pkgmetadata>
-- 
cgit v1.2.3-70-g09d2