From 425162a7f7e0e1816770d93b01985e4cb6c9679c Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Tue, 7 Dec 2021 13:44:01 -0500
Subject: media-gfx/gthumb: import

---
 media-gfx/gthumb/Manifest             |  2 +
 media-gfx/gthumb/gthumb-3.10.4.ebuild | 97 +++++++++++++++++++++++++++++++++++
 media-gfx/gthumb/metadata.xml         | 12 +++++
 3 files changed, 111 insertions(+)
 create mode 100644 media-gfx/gthumb/Manifest
 create mode 100644 media-gfx/gthumb/gthumb-3.10.4.ebuild
 create mode 100644 media-gfx/gthumb/metadata.xml

(limited to 'media-gfx')

diff --git a/media-gfx/gthumb/Manifest b/media-gfx/gthumb/Manifest
new file mode 100644
index 0000000..ddfcec7
--- /dev/null
+++ b/media-gfx/gthumb/Manifest
@@ -0,0 +1,2 @@
+DIST gthumb-3.10.3.tar.xz 7582472 BLAKE2B 1e8274720428db05d4e14bb6a37ff55a74fe009ea551bda6fe75506f7187e03685903c2743fb6e66a33da73c974188528afad866c568bb14cc6f05749e08af7c SHA512 2d157644c6efbf4f4ab31c525a4eecc69fbdf31003f922d5fdf8866ca6bbb44e5b8bd7f809be12de41178ddcef30bb49029ea06eb4feb8398a6aa1b052c6ae38
+DIST gthumb-3.10.4.tar.xz 7581416 BLAKE2B 7afc94c18d819a5eef7d075489533cf99e7f6d5eaf409b163524a2f62d9c22a40edbc114b16d6d7b7960df53d49cefda9196ebeaa2bc0c19e5760f584628209b SHA512 90f7d83d2fb6db12ef16e5ce29d9310ed5aaccb269004d72df985dda839c1ce738354942f537a23f63cbe724a351a0f13f2eb1e659ada50196af1bc60d5c5d27
diff --git a/media-gfx/gthumb/gthumb-3.10.4.ebuild b/media-gfx/gthumb/gthumb-3.10.4.ebuild
new file mode 100644
index 0000000..7971a89
--- /dev/null
+++ b/media-gfx/gthumb/gthumb-3.10.4.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Image viewer and browser for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gthumb"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cdr colord exif gnome-keyring gstreamer http lcms raw slideshow svg tiff webp"
+
+RDEPEND="
+	>=dev-libs/glib-2.54.0:2
+	>=x11-libs/gtk+-3.16.0:3
+	exif? ( >=media-gfx/exiv2-0.21:= )
+	slideshow? (
+		>=media-libs/clutter-1.12.0:1.0
+		>=media-libs/clutter-gtk-1:1.0
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-gtk:1.0
+	)
+	raw? ( >=media-libs/libraw-0.14:=
+		<media-libs/libraw-0.21 )
+	http? (
+		>=net-libs/libsoup-2.42.0:2.4
+		>=dev-libs/json-glib-0.15.0
+		>=net-libs/webkit-gtk-1.10.0:4
+	)
+	gnome-keyring? ( >=app-crypt/libsecret-0.11 )
+	cdr? ( >=app-cdr/brasero-3.2.0 )
+	svg? ( >=gnome-base/librsvg-2.34:2 )
+	webp? ( >=media-libs/libwebp-0.2.0:= )
+	lcms? ( >=media-libs/lcms-2.6:2 )
+	colord? (
+		>=x11-misc/colord-1.3
+		>=media-libs/lcms-2.6:2
+	)
+
+	sys-libs/zlib
+	virtual/jpeg:0=
+	tiff? ( media-libs/tiff:= )
+	media-libs/libpng:0=
+	>=gnome-base/gsettings-desktop-schemas-0.1.4
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/itstool
+	sys-devel/bison
+	sys-devel/flex
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Drun-in-place=false
+		$(meson_use exif exiv2)
+		$(meson_use slideshow clutter)
+		$(meson_use gstreamer)
+		-Dlibchamplain=false # Upstream still doesn't seem to consider this ready
+		$(meson_use colord)
+		$(meson_use tiff libtiff)
+		$(meson_use webp libwebp)
+		$(meson_use raw libraw)
+		$(meson_use svg librsvg)
+		$(meson_use gnome-keyring libsecret)
+		$(meson_use http webservices)
+		$(meson_use cdr libbrasero)
+	)
+
+	# colord pulls in lcms2 anyway, so enable lcms with USE="colord -lcms"; some of upstream HAVE_COLORD code depends on HAVE_LCMS2
+	if use lcms || use colord; then
+		emesonargs+=( -Dlcms2=true )
+	else
+		emesonargs+=( -Dlcms2=false )
+	fi
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/media-gfx/gthumb/metadata.xml b/media-gfx/gthumb/metadata.xml
new file mode 100644
index 0000000..d03ecf7
--- /dev/null
+++ b/media-gfx/gthumb/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>gnome@gentoo.org</email>
+		<name>Gentoo GNOME Desktop</name>
+	</maintainer>
+	<use>
+		<flag name="http">Enable webservice integration through <pkg>net-libs/webkit-gtk</pkg></flag>
+		<flag name="slideshow">Enable slideshow plugin</flag>
+	</use>
+</pkgmetadata>
-- 
cgit v1.2.3-54-g00ecf