From 2706f3abb97bb7e281f4a7b7a01f1d9ba36676c5 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Sat, 6 Nov 2021 10:48:14 -0400
Subject: media-libs/libjxl: 0.6.1

---
 media-libs/libjxl/Manifest            |   2 +-
 media-libs/libjxl/libjxl-0.6.1.ebuild | 119 ++++++++++++++++++++++++++++++++++
 media-libs/libjxl/libjxl-0.6.ebuild   | 119 ----------------------------------
 3 files changed, 120 insertions(+), 120 deletions(-)
 create mode 100644 media-libs/libjxl/libjxl-0.6.1.ebuild
 delete mode 100644 media-libs/libjxl/libjxl-0.6.ebuild

(limited to 'media-libs/libjxl')

diff --git a/media-libs/libjxl/Manifest b/media-libs/libjxl/Manifest
index 05256c8..59541c9 100644
--- a/media-libs/libjxl/Manifest
+++ b/media-libs/libjxl/Manifest
@@ -1,2 +1,2 @@
-DIST libjxl-0.6.tar.gz 16953410 BLAKE2B 8941987f6d31096a7286f9d98cdcc16e5fe338e6b3d966343f97fc5b5b932ec92c994fab5781448aa7d96324e5c9ce5c83754b01cf6e752d0702ce9fc0a2087f SHA512 934c86d079c7a1f5382fad158efac225b9d1b27e551ea85ea7ec43e7ffd5cba85ddbfa35658b242a9f9c9589decf245568349abfa8a4fe12898af78d51608852
+DIST libjxl-0.6.1.tar.gz 16953185 BLAKE2B d1e906480e80458635a65bd89ce79f13d463e8cf4fb0dfccf6c473e7649fdc5593669effdf85afbb176920c89e61c65c4907834225f7c9e6da4c611996b201e3 SHA512 302935d722160b0b288ac63301f9e95caf82eccf6ad76c4f4da6316a0314ee3562115932b1ceacb0d02708de0a07788992d3478cae73af0b90193f5769f9fb52
 DIST lodepng-48e5364ef48ec2408f44c727657ac1b6703185f8.tar.gz 240079 BLAKE2B 08240bd72d22f789bc0e06ed1d641fbca21ca674697880d4f004e4e76bb1b6cf595e931d2447544d896c79576e942db3cbdcca91d717f4ad8ddcfbd6c5bdc97e SHA512 50a515f1f15122fa017637be30df0db05980d07f8891f16b0b68697ef0df797176bbe005df623e9f2dbb68b750b0a87e69c3cef215c7bf15187d00491c4023c7
diff --git a/media-libs/libjxl/libjxl-0.6.1.ebuild b/media-libs/libjxl/libjxl-0.6.1.ebuild
new file mode 100644
index 0000000..a931ef9
--- /dev/null
+++ b/media-libs/libjxl/libjxl-0.6.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib java-pkg-opt-2
+
+DESCRIPTION="JPEG XL image format reference implementation"
+HOMEPAGE="https://github.com/libjxl/libjxl"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/libjxl/libjxl.git"
+	EGIT_SUBMODULES=(third_party/lodepng)
+else
+	LODEPNG_COMMIT="48e5364ef48ec2408f44c727657ac1b6703185f8"
+	SRC_URI="
+		https://github.com/libjxl/libjxl/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+		https://github.com/lvandeve/lodepng/archive/${LODEPNG_COMMIT}.tar.gz -> lodepng-${LODEPNG_COMMIT}.tar.gz
+	"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+IUSE="apng doc gif java +jpeg +man openexr static-libs test viewers"
+
+RDEPEND="app-arch/brotli[${MULTILIB_USEDEP}]
+	dev-cpp/highway[${MULTILIB_USEDEP}]
+	media-libs/lcms[${MULTILIB_USEDEP}]
+	apng? (
+		media-libs/libpng[${MULTILIB_USEDEP}]
+		sys-libs/zlib[${MULTILIB_USEDEP}]
+	)
+	gif? ( media-libs/giflib[${MULTILIB_USEDEP}] )
+	java? ( >=virtual/jre-1.8:* )
+	jpeg? ( virtual/jpeg[${MULTILIB_USEDEP}] )
+	openexr? ( media-libs/openexr:=[${MULTILIB_USEDEP}] )
+	viewers? (
+		dev-qt/qtwidgets
+		dev-qt/qtx11extras
+	)
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	man? ( app-text/asciidoc )
+	viewers? ( kde-frameworks/extra-cmake-modules )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-cpp/gtest[${MULTILIB_USEDEP}] )
+	java? ( >=virtual/jdk-1.8:* )
+"
+
+PATCHES=(
+	"${FILESDIR}/system-lcms.patch"
+	"${FILESDIR}/roundtripanimationpatches-ifdef-gif.patch"
+)
+
+src_prepare() {
+	if [[ ${PV} != 9999 ]]; then
+		rmdir third_party/lodepng
+		ln -sv ../../lodepng-${LODEPNG_COMMIT} third_party/lodepng || die
+	fi
+	cmake_src_prepare
+	java-pkg-opt-2_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DJPEGXL_ENABLE_BENCHMARK=OFF
+		-DJPEGXL_ENABLE_COVERAGE=OFF
+		-DJPEGXL_ENABLE_EXAMPLES=OFF
+		-DJPEGXL_ENABLE_FUZZERS=OFF
+		-DJPEGXL_ENABLE_JNI=$(multilib_native_usex java ON OFF)
+		-DJPEGXL_ENABLE_MANPAGES=$(multilib_native_usex man ON OFF)
+		-DJPEGXL_ENABLE_OPENEXR=$(usex openexr ON OFF)
+		-DJPEGXL_ENABLE_PLUGINS=OFF
+		-DJPEGXL_ENABLE_SJPEG=OFF
+		-DJPEGXL_ENABLE_SKCMS=OFF
+		-DJPEGXL_ENABLE_TCMALLOC=OFF
+		-DJPEGXL_ENABLE_VIEWERS=$(multilib_native_usex viewers ON OFF)
+		-DJPEGXL_FORCE_SYSTEM_BROTLI=ON
+		-DJPEGXL_FORCE_SYSTEM_GTEST=ON
+		-DJPEGXL_FORCE_SYSTEM_HWY=ON
+		-DJPEGXL_FORCE_SYSTEM_LCMS=ON
+		-DJPEGXL_WARNINGS_AS_ERRORS=OFF
+
+		$(cmake_use_find_package apng PNG)
+		$(cmake_use_find_package apng ZLIB)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=$(multilib_native_usex doc OFF ON)
+		$(cmake_use_find_package gif GIF)
+		$(cmake_use_find_package jpeg JPEG)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_test() {
+	# DecodeTest.PixelTestWithICCProfileLossy: https://github.com/libjxl/libjxl/issues/500
+	# RobustStatisticsTest: https://github.com/libjxl/libjxl/issues/698
+	local myctestargs=(
+		-E '^DecodeTest\.PixelTestWithICCProfileLossy$|^RobustStatisticsTest\.'
+	)
+	cmake_src_test
+}
+
+multilib_src_install() {
+	cmake_src_install
+	if ! use static-libs; then
+		rm "${ED}"/usr/$(get_libdir)/libjxl{,_dec}.a || die
+	fi
+	if use java && multilib_is_native_abi; then
+		java-pkg_doso tools/libjxl_jni.so
+	fi
+}
diff --git a/media-libs/libjxl/libjxl-0.6.ebuild b/media-libs/libjxl/libjxl-0.6.ebuild
deleted file mode 100644
index a931ef9..0000000
--- a/media-libs/libjxl/libjxl-0.6.ebuild
+++ /dev/null
@@ -1,119 +0,0 @@
-# Copyright 2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-CMAKE_ECLASS=cmake
-inherit cmake-multilib java-pkg-opt-2
-
-DESCRIPTION="JPEG XL image format reference implementation"
-HOMEPAGE="https://github.com/libjxl/libjxl"
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/libjxl/libjxl.git"
-	EGIT_SUBMODULES=(third_party/lodepng)
-else
-	LODEPNG_COMMIT="48e5364ef48ec2408f44c727657ac1b6703185f8"
-	SRC_URI="
-		https://github.com/libjxl/libjxl/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
-		https://github.com/lvandeve/lodepng/archive/${LODEPNG_COMMIT}.tar.gz -> lodepng-${LODEPNG_COMMIT}.tar.gz
-	"
-fi
-
-LICENSE="Apache-2.0"
-SLOT="0"
-if [[ ${PV} != 9999 ]]; then
-	KEYWORDS="~amd64 ~x86"
-fi
-IUSE="apng doc gif java +jpeg +man openexr static-libs test viewers"
-
-RDEPEND="app-arch/brotli[${MULTILIB_USEDEP}]
-	dev-cpp/highway[${MULTILIB_USEDEP}]
-	media-libs/lcms[${MULTILIB_USEDEP}]
-	apng? (
-		media-libs/libpng[${MULTILIB_USEDEP}]
-		sys-libs/zlib[${MULTILIB_USEDEP}]
-	)
-	gif? ( media-libs/giflib[${MULTILIB_USEDEP}] )
-	java? ( >=virtual/jre-1.8:* )
-	jpeg? ( virtual/jpeg[${MULTILIB_USEDEP}] )
-	openexr? ( media-libs/openexr:=[${MULTILIB_USEDEP}] )
-	viewers? (
-		dev-qt/qtwidgets
-		dev-qt/qtx11extras
-	)
-"
-BDEPEND="
-	doc? ( app-doc/doxygen )
-	man? ( app-text/asciidoc )
-	viewers? ( kde-frameworks/extra-cmake-modules )
-"
-DEPEND="${RDEPEND}
-	test? ( dev-cpp/gtest[${MULTILIB_USEDEP}] )
-	java? ( >=virtual/jdk-1.8:* )
-"
-
-PATCHES=(
-	"${FILESDIR}/system-lcms.patch"
-	"${FILESDIR}/roundtripanimationpatches-ifdef-gif.patch"
-)
-
-src_prepare() {
-	if [[ ${PV} != 9999 ]]; then
-		rmdir third_party/lodepng
-		ln -sv ../../lodepng-${LODEPNG_COMMIT} third_party/lodepng || die
-	fi
-	cmake_src_prepare
-	java-pkg-opt-2_src_prepare
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DBUILD_TESTING=$(usex test ON OFF)
-		-DJPEGXL_ENABLE_BENCHMARK=OFF
-		-DJPEGXL_ENABLE_COVERAGE=OFF
-		-DJPEGXL_ENABLE_EXAMPLES=OFF
-		-DJPEGXL_ENABLE_FUZZERS=OFF
-		-DJPEGXL_ENABLE_JNI=$(multilib_native_usex java ON OFF)
-		-DJPEGXL_ENABLE_MANPAGES=$(multilib_native_usex man ON OFF)
-		-DJPEGXL_ENABLE_OPENEXR=$(usex openexr ON OFF)
-		-DJPEGXL_ENABLE_PLUGINS=OFF
-		-DJPEGXL_ENABLE_SJPEG=OFF
-		-DJPEGXL_ENABLE_SKCMS=OFF
-		-DJPEGXL_ENABLE_TCMALLOC=OFF
-		-DJPEGXL_ENABLE_VIEWERS=$(multilib_native_usex viewers ON OFF)
-		-DJPEGXL_FORCE_SYSTEM_BROTLI=ON
-		-DJPEGXL_FORCE_SYSTEM_GTEST=ON
-		-DJPEGXL_FORCE_SYSTEM_HWY=ON
-		-DJPEGXL_FORCE_SYSTEM_LCMS=ON
-		-DJPEGXL_WARNINGS_AS_ERRORS=OFF
-
-		$(cmake_use_find_package apng PNG)
-		$(cmake_use_find_package apng ZLIB)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=$(multilib_native_usex doc OFF ON)
-		$(cmake_use_find_package gif GIF)
-		$(cmake_use_find_package jpeg JPEG)
-	)
-
-	cmake_src_configure
-}
-
-multilib_src_test() {
-	# DecodeTest.PixelTestWithICCProfileLossy: https://github.com/libjxl/libjxl/issues/500
-	# RobustStatisticsTest: https://github.com/libjxl/libjxl/issues/698
-	local myctestargs=(
-		-E '^DecodeTest\.PixelTestWithICCProfileLossy$|^RobustStatisticsTest\.'
-	)
-	cmake_src_test
-}
-
-multilib_src_install() {
-	cmake_src_install
-	if ! use static-libs; then
-		rm "${ED}"/usr/$(get_libdir)/libjxl{,_dec}.a || die
-	fi
-	if use java && multilib_is_native_abi; then
-		java-pkg_doso tools/libjxl_jni.so
-	fi
-}
-- 
cgit v1.2.3-70-g09d2