From af42e1bcf3abc427f046cebd15a0e4c8dc6cc268 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Tue, 1 Oct 2024 15:17:29 -0400
Subject: sci-calculators/units: upgrade to 2.23

---
 sci-calculators/units/units-2.23-r1.ebuild | 57 ++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 sci-calculators/units/units-2.23-r1.ebuild

(limited to 'sci-calculators/units/units-2.23-r1.ebuild')

diff --git a/sci-calculators/units/units-2.23-r1.ebuild b/sci-calculators/units/units-2.23-r1.ebuild
new file mode 100644
index 0000000..c5ddc81
--- /dev/null
+++ b/sci-calculators/units/units-2.23-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit python-r1
+
+DESCRIPTION="Unit conversion program"
+HOMEPAGE="https://www.gnu.org/software/units/units.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="FDL-1.3 GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+units-cur"
+REQUIRED_USE="units-cur? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	sys-libs/readline:=
+	units-cur? (
+		${PYTHON_DEPS}
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.20-readerror.patch
+	"${FILESDIR}"/units_cur-urllib.patch
+)
+
+DOCS=( NEWS README )
+
+src_configure() {
+	local myconf=(
+		--sharedstatedir="${EPREFIX}"/var/lib
+		ac_cv_path_PYTHON=no
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	emake ${PN}
+}
+
+src_install() {
+	default
+
+	if use units-cur; then
+		sed \
+			-e "/^outfile/s|'.*'|'/usr/share/units/currency.units'|g" \
+			-e 's|^#!|&/usr/bin/python|g' \
+			units_cur_inst > units_cur || die
+		python_foreach_impl python_doscript units_cur
+	fi
+}
-- 
cgit v1.2.3-70-g09d2