From 306371270cfb97f28c31341109257ed680fd2df3 Mon Sep 17 00:00:00 2001
From: "Alex Xu (Hello71)" <alex_y_xu@yahoo.ca>
Date: Thu, 15 Oct 2020 09:53:07 -0400
Subject: Revert "x11-apps/mesa-progs: drop, fixed upstream"

This reverts commit ca1db4f63cea11f7894c726168175cdffe4638a6.
---
 x11-apps/mesa-progs/mesa-progs-9999.ebuild | 64 ++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 x11-apps/mesa-progs/mesa-progs-9999.ebuild

(limited to 'x11-apps/mesa-progs/mesa-progs-9999.ebuild')

diff --git a/x11-apps/mesa-progs/mesa-progs-9999.ebuild b/x11-apps/mesa-progs/mesa-progs-9999.ebuild
new file mode 100644
index 0000000..a20e558
--- /dev/null
+++ b/x11-apps/mesa-progs/mesa-progs-9999.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_PN="${PN/progs/demos}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Mesa's OpenGL utility and demo programs (glxgears and glxinfo)"
+HOMEPAGE="https://www.mesa3d.org/ https://mesa.freedesktop.org/ https://gitlab.freedesktop.org/mesa/demos"
+if [[ ${PV} = 9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/demos.git"
+	EGIT_CHECKOUT_DIR="${S}"
+	EXPERIMENTAL="true"
+else
+	SRC_URI="https://mesa.freedesktop.org/archive/demos/${MY_P}.tar.bz2
+		https://mesa.freedesktop.org/archive/demos/${PV}/${MY_P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${MY_P}"
+fi
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="egl gles2"
+
+RDEPEND="
+	media-libs/glew:=
+	media-libs/mesa[egl?,gles2?]
+	virtual/opengl
+	x11-libs/libX11"
+DEPEND="${RDEPEND}
+	virtual/glu
+	x11-base/xorg-proto"
+
+src_prepare() {
+	default
+	[[ $PV = 9999* ]] && eautoreconf
+}
+
+src_compile() {
+	emake -C src/xdemos glxgears glxinfo
+
+	if use egl; then
+		emake LDLIBS="-lEGL" -C src/egl/opengl/ eglinfo
+		emake -C src/egl/eglut/ libeglut_x11.la
+		emake LDLIBS="-lGL -lEGL -lX11 -lm" -C src/egl/opengl/ eglgears_x11
+
+		if use gles2; then
+			emake LDLIBS="-lGLESv2 -lEGL -lX11" -C src/egl/opengles2/ es2_info
+			emake LDLIBS="-lGLESv2 -lEGL -lX11 -lm" -C src/egl/opengles2/ es2gears_x11
+		fi
+	fi
+}
+
+src_install() {
+	dobin src/xdemos/{glxgears,glxinfo}
+	if use egl; then
+		dobin src/egl/opengl/egl{info,gears_x11}
+
+		use gles2 && dobin src/egl/opengles2/es2{_info,gears_x11}
+	fi
+}
-- 
cgit v1.2.3-54-g00ecf