# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
PYTHON_COMPAT=( python3_{7..10} )

inherit systemd autotools gnome2-utils python-r1

DESCRIPTION="A screen color temperature adjusting software"
HOMEPAGE="https://gitlab.com/chinstrap/gammastep/"
SRC_URI="https://gitlab.com/chinstrap/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="X appindicator drm geoclue gtk nls wayland"

BDEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.50
	nls? ( sys-devel/gettext )
"
DEPEND="
	X? (
		>=x11-libs/libX11-1.4
		x11-libs/libXxf86vm
		x11-libs/libxcb
	)
	appindicator? ( dev-libs/libappindicator:3[introspection] )
	drm? ( x11-libs/libdrm )
	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
	gtk? ( ${PYTHON_DEPS} )
	wayland? ( >=dev-libs/wayland-1.15.0 )"
RDEPEND="${DEPEND}
	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
		x11-libs/gtk+:3[introspection]
		dev-python/pyxdg[${PYTHON_USEDEP}] )"
REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"

S="${WORKDIR}/${PN}-v${PV}"

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	use gtk && python_setup

	econf \
		$(use_enable nls) \
		$(use_enable drm) \
		$(use_enable X randr) \
		$(use_enable X vidmode) \
		$(use_enable geoclue geoclue2) \
		$(use_enable gtk gui) \
		$(use_enable wayland) \
		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
		--enable-apparmor
}

_impl_specific_src_install() {
	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
			-C src/gammastep_indicator install
}

src_install() {
	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install

	if use gtk; then
		python_foreach_impl _impl_specific_src_install
		python_replicate_script "${D}"/usr/bin/gammastep-indicator

		python_foreach_impl python_optimize
	fi
}

pkg_preinst() {
	use gtk && gnome2_icon_savelist
}

pkg_postinst() {
	use gtk && gnome2_icon_cache_update
}

pkg_postrm() {
	use gtk && gnome2_icon_cache_update
}