media-video/ffmpeg: drop

3 files changed, 0 insertions, 702 deletions

diff --git a/media-video/ffmpeg/ffmpeg-9999.ebuild b/media-video/ffmpeg/ffmpeg-9999.ebuild
deleted file mode 100644
index daed6ca..0000000
--- a/media-video/ffmpeg/ffmpeg-9999.ebuild
+++ /dev/null
@@ -1,589 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-# Subslot: libavutil major.libavcodec major.libavformat major
-# Since FFmpeg ships several libraries, subslot is kind of limited here.
-# Most consumers will use those three libraries, if a "less used" library
-# changes its soname, consumers will have to be rebuilt the old way
-# (preserve-libs).
-# If, for example, a package does not link to libavformat and only libavformat
-# changes its ABI then this package will be rebuilt needlessly. Hence, such a
-# package is free _not_ to := depend on FFmpeg but I would strongly encourage
-# doing so since such a case is unlikely.
-FFMPEG_SUBSLOT=57.59.59
-
-SCM=""
-if [ "${PV#9999}" != "${PV}" ] ; then
-	SCM="git-r3"
-	EGIT_MIN_CLONE_TYPE="single"
-	EGIT_REPO_URI="https://git.ffmpeg.org/ffmpeg.git"
-fi
-
-inherit flag-o-matic multilib multilib-minimal toolchain-funcs ${SCM}
-
-DESCRIPTION="Complete solution to record/convert/stream audio and video. Includes libavcodec"
-HOMEPAGE="https://ffmpeg.org/"
-if [ "${PV#9999}" != "${PV}" ] ; then
-	SRC_URI=""
-elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
-	SRC_URI="mirror://gentoo/${P}.tar.xz"
-else # Release
-	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/ffmpeg.asc
-	inherit verify-sig
-	SRC_URI="https://ffmpeg.org/releases/${P/_/-}.tar.xz"
-	SRC_URI+=" verify-sig? ( https://ffmpeg.org/releases/${P/_/-}.tar.xz.asc )"
-
-	BDEPEND=" verify-sig? ( sec-keys/openpgp-keys-ffmpeg )"
-fi
-FFMPEG_REVISION="${PV#*_p}"
-
-SLOT="0/${FFMPEG_SUBSLOT}"
-LICENSE="
-	!gpl? ( LGPL-2.1 )
-	gpl? ( GPL-2 )
-	amr? (
-		gpl? ( GPL-3 )
-		!gpl? ( LGPL-3 )
-	)
-	gmp? (
-		gpl? ( GPL-3 )
-		!gpl? ( LGPL-3 )
-	)
-	libaribb24? (
-		gpl? ( GPL-3 )
-		!gpl? ( LGPL-3 )
-	)
-	encode? (
-		amrenc? (
-			gpl? ( GPL-3 )
-			!gpl? ( LGPL-3 )
-		)
-	)
-	samba? ( GPL-3 )
-"
-if [ "${PV#9999}" = "${PV}" ] ; then
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
-fi
-
-# Options to use as use_enable in the foo[:bar] form.
-# This will feed configure with $(use_enable foo bar)
-# or $(use_enable foo foo) if no :bar is set.
-# foo is added to IUSE.
-FFMPEG_FLAG_MAP=(
-		+bzip2:bzlib cpudetection:runtime-cpudetect debug gcrypt +gnutls gmp
-		+gpl hardcoded-tables +iconv libxml2 lzma +network opencl
-		openssl +postproc samba:libsmbclient sdl:ffplay sdl:sdl2 vaapi vdpau vulkan
-		X:xlib X:libxcb X:libxcb-shm X:libxcb-xfixes +zlib
-		# libavdevice options
-		cdio:libcdio iec61883:libiec61883 ieee1394:libdc1394 libcaca openal
-		opengl
-		# indevs
-		libv4l:libv4l2 pulseaudio:libpulse libdrm jack:libjack
-		# decoders
-		amr:libopencore-amrwb amr:libopencore-amrnb codec2:libcodec2 +dav1d:libdav1d fdk:libfdk-aac
-		jpeg2k:libopenjpeg jpegxl:libjxl bluray:libbluray gme:libgme gsm:libgsm
-		libaribb24 mmal modplug:libmodplug opus:libopus libilbc librtmp ssh:libssh
-		speex:libspeex srt:libsrt svg:librsvg nvenc:ffnvcodec
-		vorbis:libvorbis vpx:libvpx zvbi:libzvbi
-		# libavfilter options
-		appkit
-		bs2b:libbs2b chromaprint cuda:cuda-llvm flite:libflite frei0r vmaf:libvmaf
-		fribidi:libfribidi fontconfig ladspa libass libtesseract lv2 truetype:libfreetype vidstab:libvidstab
-		rubberband:librubberband zeromq:libzmq zimg:libzimg
-		# libswresample options
-		libsoxr
-		# Threads; we only support pthread for now but ffmpeg supports more
-		+threads:pthreads
-)
-
-# Same as above but for encoders, i.e. they do something only with USE=encode.
-FFMPEG_ENCODER_FLAG_MAP=(
-	amf amrenc:libvo-amrwbenc kvazaar:libkvazaar libaom	mp3:libmp3lame
-	openh264:libopenh264 rav1e:librav1e snappy:libsnappy svt-av1:libsvtav1
-	theora:libtheora twolame:libtwolame webp:libwebp x264:libx264
-	x265:libx265 xvid:libxvid
-)
-
-IUSE="
-	alsa chromium doc +encode oss pic sndio static-libs test v4l
-	${FFMPEG_FLAG_MAP[@]%:*}
-	${FFMPEG_ENCODER_FLAG_MAP[@]%:*}
-"
-
-# Strings for CPU features in the useflag[:configure_option] form
-# if :configure_option isn't set, it will use 'useflag' as configure option
-ARM_CPU_FEATURES=(
-	cpu_flags_arm_thumb:armv5te
-	cpu_flags_arm_v6:armv6
-	cpu_flags_arm_thumb2:armv6t2
-	cpu_flags_arm_neon:neon
-	cpu_flags_arm_vfp:vfp
-	cpu_flags_arm_vfpv3:vfpv3
-	cpu_flags_arm_v8:armv8
-)
-ARM_CPU_REQUIRED_USE="
-	arm64? ( cpu_flags_arm_v8 )
-	cpu_flags_arm_v8? (  cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
-	cpu_flags_arm_neon? ( cpu_flags_arm_thumb2 cpu_flags_arm_vfp )
-	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
-	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
-	cpu_flags_arm_v6? ( cpu_flags_arm_thumb )
-"
-MIPS_CPU_FEATURES=( mipsdspr1:mipsdsp mipsdspr2 mipsfpu )
-PPC_CPU_FEATURES=( cpu_flags_ppc_altivec:altivec cpu_flags_ppc_vsx:vsx cpu_flags_ppc_vsx2:power8 )
-PPC_CPU_REQUIRED_USE="
-	cpu_flags_ppc_vsx? ( cpu_flags_ppc_altivec )
-	cpu_flags_ppc_vsx2? ( cpu_flags_ppc_vsx )
-"
-X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
-X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
-X86_CPU_REQUIRED_USE="
-	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
-	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
-	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
-	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
-	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
-	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
-	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
-	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
-	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
-	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
-	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
-	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
-	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
-	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
-	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
-"
-
-CPU_FEATURES_MAP=(
-	${ARM_CPU_FEATURES[@]}
-	${MIPS_CPU_FEATURES[@]}
-	${PPC_CPU_FEATURES[@]}
-	${X86_CPU_FEATURES[@]}
-)
-IUSE="${IUSE}
-	${CPU_FEATURES_MAP[@]%:*}"
-
-CPU_REQUIRED_USE="
-	${ARM_CPU_REQUIRED_USE}
-	${PPC_CPU_REQUIRED_USE}
-	${X86_CPU_REQUIRED_USE}
-"
-
-FFTOOLS=( aviocat cws2fws ffescape ffeval ffhash fourcc2pixfmt graph2dot ismindex pktdumper qt-faststart sidxindex trasher )
-IUSE="${IUSE} ${FFTOOLS[@]/#/+fftools_}"
-
-RDEPEND="
-	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
-	amf? ( media-video/amdgpu-pro-amf )
-	amr? ( >=media-libs/opencore-amr-0.1.3-r1[${MULTILIB_USEDEP}] )
-	bluray? ( >=media-libs/libbluray-0.3.0-r1:=[${MULTILIB_USEDEP}] )
-	bs2b? ( >=media-libs/libbs2b-3.1.0-r1[${MULTILIB_USEDEP}] )
-	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
-	cdio? ( >=dev-libs/libcdio-paranoia-0.90_p1-r1[${MULTILIB_USEDEP}] )
-	chromaprint? ( >=media-libs/chromaprint-1.2-r1[${MULTILIB_USEDEP}] )
-	codec2? ( media-libs/codec2[${MULTILIB_USEDEP}] )
-	dav1d? ( >=media-libs/dav1d-0.4.0:0=[${MULTILIB_USEDEP}] )
-	encode? (
-		amrenc? ( >=media-libs/vo-amrwbenc-0.1.2-r1[${MULTILIB_USEDEP}] )
-		kvazaar? ( >=media-libs/kvazaar-1.2.0[${MULTILIB_USEDEP}] )
-		mp3? ( >=media-sound/lame-3.99.5-r1[${MULTILIB_USEDEP}] )
-		openh264? ( >=media-libs/openh264-1.4.0-r1:=[${MULTILIB_USEDEP}] )
-		rav1e? ( >=media-video/rav1e-0.4:=[capi] )
-		snappy? ( >=app-arch/snappy-1.1.2-r1:=[${MULTILIB_USEDEP}] )
-		theora? (
-			>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
-			>=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}]
-		)
-		twolame? ( >=media-sound/twolame-0.3.13-r1[${MULTILIB_USEDEP}] )
-		webp? ( >=media-libs/libwebp-0.3.0:=[${MULTILIB_USEDEP}] )
-		x264? ( >=media-libs/x264-0.0.20130506:=[${MULTILIB_USEDEP}] )
-		x265? ( >=media-libs/x265-1.6:=[${MULTILIB_USEDEP}] )
-		xvid? ( >=media-libs/xvid-1.3.2-r1[${MULTILIB_USEDEP}] )
-	)
-	fdk? ( >=media-libs/fdk-aac-0.1.3:=[${MULTILIB_USEDEP}] )
-	flite? ( >=app-accessibility/flite-1.4-r4[${MULTILIB_USEDEP}] )
-	fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
-	frei0r? ( media-plugins/frei0r-plugins[${MULTILIB_USEDEP}] )
-	fribidi? ( >=dev-libs/fribidi-0.19.6[${MULTILIB_USEDEP}] )
-	gcrypt? ( >=dev-libs/libgcrypt-1.6:0=[${MULTILIB_USEDEP}] )
-	gme? ( >=media-libs/game-music-emu-0.6.0[${MULTILIB_USEDEP}] )
-	gmp? ( >=dev-libs/gmp-6:0=[${MULTILIB_USEDEP}] )
-	gsm? ( >=media-sound/gsm-1.0.13-r1[${MULTILIB_USEDEP}] )
-	iconv? ( >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}] )
-	iec61883? (
-		>=media-libs/libiec61883-1.2.0-r1[${MULTILIB_USEDEP}]
-		>=sys-libs/libraw1394-2.1.0-r1[${MULTILIB_USEDEP}]
-		>=sys-libs/libavc1394-0.5.4-r1[${MULTILIB_USEDEP}]
-	)
-	ieee1394? (
-		>=media-libs/libdc1394-2.2.1:2=[${MULTILIB_USEDEP}]
-		>=sys-libs/libraw1394-2.1.0-r1[${MULTILIB_USEDEP}]
-	)
-	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
-	jpeg2k? ( >=media-libs/openjpeg-2:2[${MULTILIB_USEDEP}] )
-	jpegxl? ( media-libs/libjxl:=[${MULTILIB_USEDEP}] )
-	libaom? ( >=media-libs/libaom-1.0.0-r1:=[${MULTILIB_USEDEP}] )
-	libaribb24? ( >=media-libs/aribb24-1.0.3-r2[${MULTILIB_USEDEP}] )
-	libass? ( >=media-libs/libass-0.11.0:=[${MULTILIB_USEDEP}] )
-	libcaca? ( >=media-libs/libcaca-0.99_beta18-r1[${MULTILIB_USEDEP}] )
-	libdrm? ( x11-libs/libdrm[${MULTILIB_USEDEP}] )
-	libilbc? ( >=media-libs/libilbc-2[${MULTILIB_USEDEP}] )
-	librtmp? ( >=media-video/rtmpdump-2.4_p20131018[${MULTILIB_USEDEP}] )
-	libsoxr? ( >=media-libs/soxr-0.1.0[${MULTILIB_USEDEP}] )
-	libtesseract? ( >=app-text/tesseract-4.1.0-r1[${MULTILIB_USEDEP}] )
-	libv4l? ( >=media-libs/libv4l-0.9.5[${MULTILIB_USEDEP}] )
-	libxml2? ( dev-libs/libxml2:=[${MULTILIB_USEDEP}] )
-	lv2? ( media-libs/lv2[${MULTILIB_USEDEP}] media-libs/lilv[${MULTILIB_USEDEP}] )
-	lzma? ( >=app-arch/xz-utils-5.0.5-r1[${MULTILIB_USEDEP}] )
-	mmal? ( media-libs/raspberrypi-userland )
-	modplug? ( >=media-libs/libmodplug-0.8.8.4-r1[${MULTILIB_USEDEP}] )
-	openal? ( >=media-libs/openal-1.15.1[${MULTILIB_USEDEP}] )
-	opencl? ( virtual/opencl[${MULTILIB_USEDEP}] )
-	opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
-	opus? ( >=media-libs/opus-1.0.2-r2[${MULTILIB_USEDEP}] )
-	pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )
-	rubberband? ( >=media-libs/rubberband-1.8.1-r1[${MULTILIB_USEDEP}] )
-	samba? ( >=net-fs/samba-3.6.23-r1[client,${MULTILIB_USEDEP}] )
-	sdl? ( media-libs/libsdl2[sound,video,${MULTILIB_USEDEP}] )
-	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
-	speex? ( >=media-libs/speex-1.2_rc1-r1[${MULTILIB_USEDEP}] )
-	srt? ( >=net-libs/srt-1.3.0:=[${MULTILIB_USEDEP}] )
-	ssh? ( >=net-libs/libssh-0.5.5:=[sftp,${MULTILIB_USEDEP}] )
-	svg? (
-		gnome-base/librsvg:2=[${MULTILIB_USEDEP}]
-		x11-libs/cairo[${MULTILIB_USEDEP}]
-	)
-	nvenc? ( >=media-libs/nv-codec-headers-9.1.23.1 )
-	svt-av1? ( >=media-libs/svt-av1-0.8.4[${MULTILIB_USEDEP}] )
-	truetype? ( >=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}] )
-	vaapi? ( >=x11-libs/libva-1.2.1-r1:0=[${MULTILIB_USEDEP}] )
-	vdpau? ( >=x11-libs/libvdpau-0.7[${MULTILIB_USEDEP}] )
-	vidstab? ( >=media-libs/vidstab-1.1.0[${MULTILIB_USEDEP}] )
-	vmaf? ( media-libs/libvmaf[${MULTILIB_USEDEP}] )
-	vorbis? (
-		>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
-		>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
-	)
-	vpx? ( >=media-libs/libvpx-1.4.0:=[${MULTILIB_USEDEP}] )
-	vulkan? ( >=media-libs/vulkan-loader-1.2.189:=[${MULTILIB_USEDEP}] )
-	X? (
-		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
-		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
-		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
-		>=x11-libs/libxcb-1.4:=[${MULTILIB_USEDEP}]
-	)
-	postproc? ( !media-libs/libpostproc )
-	zeromq? ( >=net-libs/zeromq-4.1.6 )
-	zimg? ( >=media-libs/zimg-2.7.4:=[${MULTILIB_USEDEP}] )
-	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
-	zvbi? ( >=media-libs/zvbi-0.2.35[${MULTILIB_USEDEP}] )
-"
-
-RDEPEND="${RDEPEND}
-		openssl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
-		!openssl? ( gnutls? ( >=net-libs/gnutls-2.12.23-r6:=[${MULTILIB_USEDEP}] ) )
-"
-
-DEPEND="${RDEPEND}
-	amf? ( media-libs/amf-headers )
-	ladspa? ( >=media-libs/ladspa-sdk-1.13-r2[${MULTILIB_USEDEP}] )
-	v4l? ( sys-kernel/linux-headers )
-"
-
-# += for verify-sig above
-BDEPEND+="
-	>=sys-devel/make-3.81
-	virtual/pkgconfig
-	cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
-	cuda? ( >=sys-devel/clang-7[llvm_targets_NVPTX] )
-	doc? ( sys-apps/texinfo )
-	test? ( net-misc/wget sys-devel/bc )
-"
-
-# Code requiring FFmpeg to be built under gpl license
-GPL_REQUIRED_USE="
-	postproc? ( gpl )
-	frei0r? ( gpl )
-	cdio? ( gpl )
-	rubberband? ( gpl )
-	vidstab? ( gpl )
-	samba? ( gpl )
-	encode? (
-		x264? ( gpl )
-		x265? ( gpl )
-		xvid? ( gpl )
-	)
-"
-REQUIRED_USE="
-	cuda? ( nvenc )
-	libv4l? ( v4l )
-	fftools_cws2fws? ( zlib )
-	test? ( encode )
-	${GPL_REQUIRED_USE}
-	${CPU_REQUIRED_USE}"
-RESTRICT="
-	!test? ( test )
-	gpl? ( openssl? ( bindist ) fdk? ( bindist ) )
-"
-
-S=${WORKDIR}/${P/_/-}
-
-PATCHES=(
-	"${FILESDIR}"/chromium-r1.patch
-)
-
-MULTILIB_WRAPPED_HEADERS=(
-	/usr/include/libavutil/avconfig.h
-)
-
-build_separate_libffmpeg() {
-	use opencl
-}
-
-src_prepare() {
-	if [[ "${PV%_p*}" != "${PV}" ]] ; then # Snapshot
-		export revision=git-N-${FFMPEG_REVISION}
-	fi
-
-	default
-
-	# -fdiagnostics-color=auto gets appended after user flags which
-	# will ignore user's preference.
-	sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
-
-	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
-}
-
-multilib_src_configure() {
-	local myconf=( )
-
-	# bug 842201
-	use ia64 && tc-is-gcc && append-flags \
-		-fno-tree-ccp \
-		-fno-tree-dominator-opts \
-		-fno-tree-fre \
-		-fno-code-hoisting \
-		-fno-tree-pre \
-		-fno-tree-vrp
-
-	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
-	use openssl && myconf+=( --enable-nonfree )
-	use samba && myconf+=( --enable-version3 )
-
-	# Encoders
-	if use encode ; then
-		ffuse+=( "${FFMPEG_ENCODER_FLAG_MAP[@]}" )
-
-		# Licensing.
-		if use amrenc ; then
-			myconf+=( --enable-version3 )
-		fi
-	else
-		myconf+=( --disable-encoders )
-	fi
-
-	# Indevs
-	use v4l || myconf+=( --disable-indev=v4l2 --disable-outdev=v4l2 )
-	for i in alsa oss jack sndio ; do
-		use ${i} || myconf+=( --disable-indev=${i} )
-	done
-
-	# Outdevs
-	for i in alsa oss sndio ; do
-		use ${i} || myconf+=( --disable-outdev=${i} )
-	done
-
-	# Decoders
-	use amr && myconf+=( --enable-version3 )
-	use gmp && myconf+=( --enable-version3 )
-	use libaribb24 && myconf+=( --enable-version3 )
-	use fdk && use gpl && myconf+=( --enable-nonfree )
-
-	for i in "${ffuse[@]#+}" ; do
-		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
-	done
-
-	if use openssl ; then
-		myconf+=( --disable-gnutls )
-		has_version dev-libs/openssl:0/3 && myconf+=( --enable-version3 )
-	fi
-
-	# (temporarily) disable non-multilib deps
-	if ! multilib_is_native_abi; then
-		for i in librav1e libzmq ; do
-			myconf+=( --disable-${i} )
-		done
-	fi
-
-	# CPU features
-	for i in "${CPU_FEATURES_MAP[@]}" ; do
-		use ${i%:*} || myconf+=( --disable-${i#*:} )
-	done
-
-	if use pic ; then
-		myconf+=( --enable-pic )
-		# disable asm code if PIC is required
-		# as the provided asm decidedly is not PIC for x86.
-		[[ ${ABI} == x86 ]] && myconf+=( --disable-asm )
-	fi
-	[[ ${ABI} == x32 ]] && myconf+=( --disable-asm ) #427004
-
-	# Try to get cpu type based on CFLAGS.
-	# Bug #172723
-	# We need to do this so that features of that CPU will be better used
-	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
-	# will just ignore it.
-	for i in $(get-flag mcpu) $(get-flag march) ; do
-		[[ ${i} = native ]] && i="host" # bug #273421
-		myconf+=( --cpu=${i} )
-		break
-	done
-
-	# LTO support, bug #566282, bug #754654
-	is-flagq "-flto*" && myconf+=( "--enable-lto" )
-	filter-flags "-flto*"
-
-	# Mandatory configuration
-	myconf=(
-		--enable-avfilter
-		--disable-stripping
-		# This is only for hardcoded cflags; those are used in configure checks that may
-		# interfere with proper detections, bug #671746 and bug #645778
-		# We use optflags, so that overrides them anyway.
-		--disable-optimizations
-		--disable-libcelt # bug #664158
-		"${myconf[@]}"
-	)
-
-	# cross compile support
-	if tc-is-cross-compiler ; then
-		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
-		case ${CHOST} in
-			*freebsd*)
-				myconf+=( --target-os=freebsd )
-				;;
-			*mingw32*)
-				myconf+=( --target-os=mingw32 )
-				;;
-			*linux*)
-				myconf+=( --target-os=linux )
-				;;
-		esac
-	fi
-
-	# doc
-	myconf+=(
-		$(multilib_native_use_enable doc)
-		$(multilib_native_use_enable doc htmlpages)
-		$(multilib_native_enable manpages)
-	)
-
-	# Fixed in 5.0.1? Waiting for verification from someone who hit the issue.
-	local extra_libs
-	if use arm || use ppc || use mips || [[ ${CHOST} == *i486* ]] ; then
-		# bug #782811
-		# bug #790590
-		extra_libs+="$(test-flags-CCLD -latomic) "
-	fi
-
-	set -- "${S}/configure" \
-		--prefix="${EPREFIX}/usr" \
-		--libdir="${EPREFIX}/usr/$(get_libdir)" \
-		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
-		--docdir="${EPREFIX}/usr/share/doc/${PF}/html" \
-		--mandir="${EPREFIX}/usr/share/man" \
-		--enable-shared \
-		--cc="$(tc-getCC)" \
-		--cxx="$(tc-getCXX)" \
-		--ar="$(tc-getAR)" \
-		--nm="$(tc-getNM)" \
-		--strip="$(tc-getSTRIP)" \
-		--ranlib="$(tc-getRANLIB)" \
-		--pkg-config="$(tc-getPKG_CONFIG)" \
-		--optflags="${CFLAGS}" \
-		--extra-libs="${extra_libs}" \
-		$(use_enable static-libs static) \
-		"${myconf[@]}" \
-		${EXTRA_FFMPEG_CONF}
-	echo "${@}"
-	"${@}" || die
-
-	if multilib_is_native_abi && use chromium && build_separate_libffmpeg; then
-		einfo "Configuring for Chromium"
-		mkdir -p ../chromium || die
-		pushd ../chromium >/dev/null || die
-		set -- "${@}" \
-			--disable-shared \
-			--enable-static \
-			--enable-pic \
-			--disable-opencl
-		echo "${@}"
-		"${@}" || die
-		popd >/dev/null || die
-	fi
-}
-
-multilib_src_compile() {
-	emake V=1
-
-	if multilib_is_native_abi; then
-		for i in "${FFTOOLS[@]}" ; do
-			if use fftools_${i} ; then
-				emake V=1 tools/${i}$(get_exeext)
-			fi
-		done
-
-		if use chromium; then
-			if build_separate_libffmpeg; then
-				einfo "Compiling for Chromium"
-				pushd ../chromium >/dev/null || die
-				emake V=1 libffmpeg
-				popd >/dev/null || die
-			else
-				emake V=1 libffmpeg
-			fi
-		fi
-	fi
-}
-
-multilib_src_test() {
-	LD_LIBRARY_PATH="${BUILD_DIR}/libpostproc:${BUILD_DIR}/libswscale:${BUILD_DIR}/libswresample:${BUILD_DIR}/libavcodec:${BUILD_DIR}/libavdevice:${BUILD_DIR}/libavfilter:${BUILD_DIR}/libavformat:${BUILD_DIR}/libavutil" \
-		emake V=1 fate
-}
-
-multilib_src_install() {
-	emake V=1 DESTDIR="${D}" install install-doc
-
-	if multilib_is_native_abi; then
-		for i in "${FFTOOLS[@]}" ; do
-			if use fftools_${i} ; then
-				dobin tools/${i}$(get_exeext)
-			fi
-		done
-
-		if use chromium; then
-			if build_separate_libffmpeg; then
-				einfo "Installing for Chromium"
-				pushd ../chromium >/dev/null || die
-				emake V=1 DESTDIR="${D}" install-libffmpeg
-				popd >/dev/null || die
-			else
-				emake V=1 DESTDIR="${D}" install-libffmpeg
-
-				# When not built separately, libffmpeg has no code of
-				# its own so this QA check raises a false positive.
-				QA_FLAGS_IGNORED+=" usr/$(get_libdir)/chromium/.*"
-			fi
-		fi
-	fi
-}
-
-multilib_src_install_all() {
-	dodoc Changelog README.md CREDITS doc/*.txt doc/APIchanges
-	[ -f "RELEASE_NOTES" ] && dodoc "RELEASE_NOTES"
-
-	use amf && doenvd "${FILESDIR}"/amf-env-vulkan-override
-}
diff --git a/media-video/ffmpeg/files/chromium-r1.patch b/media-video/ffmpeg/files/chromium-r1.patch
deleted file mode 100644
index 5147800..0000000
--- a/media-video/ffmpeg/files/chromium-r1.patch
+++ /dev/null
@@ -1,42 +0,0 @@
-Allow libffmpeg to be built for Chromium-based browsers
-https://patchwork.ffmpeg.org/patch/4500/
-
-NOTE: This patch lacks the Makefile include line. We append it
-manually instead to make patching across different versions easier.
-
-diff --git a/ffbuild/libffmpeg.mak b/ffbuild/libffmpeg.mak
-new file mode 100644
-index 0000000..992cf3c
---- /dev/null
-+++ b/ffbuild/libffmpeg.mak
-@@ -0,0 +1,27 @@
-+LIBFFMPEG = $(SLIBPREF)ffmpeg$(SLIBSUF)
-+LIBFFMPEG_LINK = $(LD) -shared -Wl,-soname,$(LIBFFMPEG) -Wl,-Bsymbolic -Wl,-z,now -Wl,-z,relro -Wl,-z,defs -Wl,--gc-sections $(LDFLAGS) $(LDLIBFLAGS) -o $(LIBFFMPEG)
-+
-+ifeq ($(CONFIG_SHARED),yes)
-+LIBFFMPEG_DEPS = libavcodec/$(SLIBPREF)avcodec$(SLIBSUF) libavformat/$(SLIBPREF)avformat$(SLIBSUF) libavutil/$(SLIBPREF)avutil$(SLIBSUF)
-+else
-+LIBFFMPEG_DEPS = libavcodec/$(LIBPREF)avcodec$(LIBSUF) libavformat/$(LIBPREF)avformat$(LIBSUF) libavutil/$(LIBPREF)avutil$(LIBSUF) libswresample/$(LIBPREF)swresample$(LIBSUF)
-+endif
-+
-+$(LIBFFMPEG): $(LIBFFMPEG_DEPS)
-+ifeq ($(CONFIG_SHARED),yes)
-+	$(LIBFFMPEG_LINK) -Wl,--no-as-needed -lavcodec -lavformat -lavutil
-+else
-+	$(LIBFFMPEG_LINK) -Wl,--whole-archive $^ -Wl,--no-whole-archive $(EXTRALIBS-avcodec) $(EXTRALIBS-avformat) $(EXTRALIBS-avutil) $(EXTRALIBS-swresample)
-+endif
-+
-+libffmpeg: $(LIBFFMPEG)
-+
-+install-libffmpeg: $(LIBFFMPEG)
-+	$(Q)mkdir -p "$(SHLIBDIR)/chromium"
-+	$(INSTALL) -m 755 $< "$(SHLIBDIR)/chromium/$<"
-+	$(STRIP) "$(SHLIBDIR)/chromium/$<"
-+
-+uninstall-libffmpeg:
-+	$(RM) "$(SHLIBDIR)/chromium/$(LIBFFMPEG)"
-+
-+.PHONY: libffmpeg install-libffmpeg uninstall-libffmpeg
--- 
-2.13.1
-
diff --git a/media-video/ffmpeg/metadata.xml b/media-video/ffmpeg/metadata.xml
deleted file mode 100644
index e6d40f8..0000000
--- a/media-video/ffmpeg/metadata.xml
+++ /dev/null
@@ -1,71 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-<use>
-	<flag name="amf">Enables support for AMD's Advanced Media Framework (AMF)</flag>
-	<flag name="amr">Enables Adaptive Multi-Rate Audio support</flag>
-	<flag name="amrenc">Enables Adaptive Multi-Rate Audio encoding support with <pkg>media-libs/vo-amrwbenc</pkg>.</flag>
-	<flag name="appkit">Enables Apple AppKit framework</flag>
-	<flag name="bluray">Enable playback of Blu-ray filesystems</flag>
-	<flag name="bs2b">Enables <pkg>media-libs/libbs2b</pkg> based Bauer stereo-to-binaural filter.</flag>
-	<flag name="cdio">Enables audio CD grabbing with <pkg>dev-libs/libcdio</pkg>.</flag>
-	<flag name="chromaprint">Enables audio fingerprinting support with <pkg>media-libs/chromaprint</pkg>.</flag>
-	<flag name="chromium">Builds libffmpeg.so to enable media playback in Chromium-based browsers like Opera and Vivaldi.</flag>
-	<flag name="codec2">Enables codec2 low bit rate speech codec support via <pkg>media-libs/codec2</pkg>.</flag>
-	<flag name="cpudetection">Enables runtime CPU detection (useful for bindist, compatibility on other CPUs)</flag>
-	<flag name="cuda">Enables CUDA-based acceleration. Mostly used for specific filters.</flag>
-	<flag name="dav1d">Enables AV1 decoding via <pkg>media-libs/dav1d</pkg>.</flag>
-	<flag name="fdk">Use external fdk-aac library for AAC encoding</flag>
-	<flag name="flite">Adds a text-to-speech filter based on <pkg>app-accessibility/flite</pkg>.</flag>
-	<flag name="frei0r">Enable frei0r wrapping in libavfilter</flag>
-	<flag name="fribidi">Enables fribidi support in the drawtext filter.</flag>
-	<flag name="gcrypt">Enables gcrypt support: Needed for rtmp(t)e support if openssl, librtmp or gmp is not used.</flag>
-	<flag name="gme">Enables support for <pkg>media-libs/game-music-emu</pkg> for playing various video game music formats.</flag>
-	<flag name="gpl">Build GPL code. Should be enabled unless you require LGPL binaries.</flag>
-	<flag name="hardcoded-tables">Use pre-calculated tables rather than calculating them on the fly.</flag>
-	<flag name="iec61883"> Support for FireWire DV/HDV input device using <pkg>media-libs/libiec61883</pkg>.</flag>
-	<flag name="jpegxl">Enables JPEG XL decoding via <pkg>media-libs/libjxl</pkg>.</flag>
-	<flag name="kvazaar">Enables <pkg>media-libs/kvazaar</pkg> based HEVC encoder.</flag>
-	<flag name="libaom">Enables <pkg>media-libs/libaom</pkg> based AV1 codec support.</flag>
-	<flag name="libaribb24">Enables ARIB text and caption decoding via <pkg>media-libs/aribb24</pkg>.</flag>
-	<flag name="libdrm">Enables <pkg>x11-libs/libdrm</pkg> support for better screen grabbing and hardware accelerated codecs.</flag>
-	<flag name="libilbc">Enables iLBC de/encoding via <pkg>media-libs/libilbc</pkg>.</flag>
-	<flag name="librtmp">Enables Real Time Messaging Protocol using librtmp (<pkg>media-video/rtmpdump</pkg>) in addition to FFmpeg's native implementation.</flag>
-	<flag name="libsoxr">Enables audio resampling through <pkg>media-libs/soxr</pkg>.</flag>
-	<flag name="libtesseract">Enables the OCR filter via <pkg>app-text/tesseract</pkg>.</flag>
-	<flag name="libv4l">Uses <pkg>media-libs/libv4l</pkg> for video4linux instead of direct calls. Adds support for more devices via the userspace library.</flag>
-	<flag name="libxml2">Uses <pkg>dev-libs/libxml2</pkg> to enable dash demuxing support.</flag>
-	<flag name="lv2">Enables lv2 audio filter wrapper.</flag>
-	<flag name="mipsdspr1">Enables MIPS DSP ASE R1 optimizations.</flag>
-	<flag name="mipsdspr2">Enables MIPS DSP ASE R2 optimizations.</flag>
-	<flag name="mipsfpu">Enables floating point MIPS optimizations.</flag>
-	<flag name="mmal">Enables Multi-Media Abstraction Layer (MMAL) decoding support: Available e.g. on the Raspberry Pi.</flag>
-	<flag name="network">Enables network streaming support</flag>
-	<flag name="opencl">Enable OpenCL support</flag>
-	<flag name="openh264">Enables H.264 encoding suppoprt via <pkg>media-libs/openh264</pkg>.</flag>
-	<flag name="openssl">Enables <pkg>dev-libs/openssl</pkg> support. Adds support for encrypted network protocols (TLS/HTTPS).</flag>
-	<flag name="pic">Force shared libraries to be built as PIC (this is slower)</flag>
-	<flag name="postproc">Build and install libpostproc.</flag>
-	<flag name="rav1e">Enables AV1 encoding support via <pkg>media-video/rav1e</pkg>.</flag>
-	<flag name="rubberband">Adds time-stretching and pitch-shifting audio filter based on <pkg>media-libs/rubberband</pkg>.</flag>
-	<flag name="snappy">Enable <pkg>app-arch/snappy</pkg> support. Required for e.g. Vidvox Hap encoder.</flag>
-	<flag name="sndio">Enable support for the <pkg>media-sound/sndio</pkg> backend</flag>
-	<flag name="srt">Enable support for Secure Reliable Transport (SRT) via <pkg>net-libs/srt</pkg></flag>
-	<flag name="ssh">Enable SSH/sftp support via <pkg>net-libs/libssh</pkg>.</flag>
-	<flag name="svt-av1">Enables AV1 encoding support via <pkg>media-libs/svt-av1</pkg>.</flag>
-	<flag name="twolame">Enables MP2 encoding via <pkg>media-sound/twolame</pkg> as an alternative to the internal encoder.</flag>
-	<flag name="vidstab">Enables video stabilization filter using vid.stab library (<pkg>media-libs/vidstab</pkg>).</flag>
-	<flag name="vmaf">Enables Netflix's perceptual video quality assessment filter using the library (<pkg>media-libs/libvmaf</pkg>).</flag>
-	<flag name="vpx">Enables VP8 and VP9 codec support using libvpx: Decoding does not require this to be enabled but libvpx can also be used for decoding; encoding requires this useflag to be enabled though.</flag>
-	<flag name="vulkan">Enables support for the vulkan API for GPU offload.</flag>
-	<flag name="x265">Enables HEVC encoding with <pkg>media-libs/x265</pkg>.</flag>
-	<flag name="zeromq">Enables <pkg>net-libs/zeromq</pkg> support with the zmq/azmq filters.</flag>
-	<flag name="zimg">Enables <pkg>media-libs/zimg</pkg> based scale filter.</flag>
-	<flag name="zvbi">Enables <pkg>media-libs/zvbi</pkg> based teletext decoder.</flag>
-</use>
-<slots>
-	<slot name="0">For building against. This is the only slot that provides
-	headers and command line tools. Binary compatibility slots come and go
-	as required, so always pin dependencies to this slot when appropriate.</slot>
-</slots>
-</pkgmetadata>