dev-java/openjdk-bin: bump

2 files changed, 104 insertions, 0 deletions

diff --git a/dev-java/openjdk-bin/Manifest b/dev-java/openjdk-bin/Manifest
index ddd22ed..4f83a41 100644
--- a/dev-java/openjdk-bin/Manifest
+++ b/dev-java/openjdk-bin/Manifest
@@ -3,3 +3,4 @@ DIST OpenJDK16U-jdk_arm_linux_hotspot_16.0.1_9.tar.gz 187587741 SHA256 20fc395d8
 DIST OpenJDK16U-jdk_ppc64le_linux_hotspot_16.0.1_9.tar.gz 186081896 SHA256 8d8e35ca5a7e24f16384bf32b110562921c19b4cfe65969980937bf879462bc6
 DIST OpenJDK16U-jdk_s390x_linux_hotspot_16.0.1_9.tar.gz 178964996 SHA256 421cd44661cdbf0c2da79ab3104c81a1fa171b974038e55b1b3d4a042865588f
 DIST OpenJDK16U-jdk_x64_linux_hotspot_16.0.1_9.tar.gz 205449187 SHA256 7fdda042207efcedd30cd76d6295ed56b9c2e248cb3682c50898a560d4aa1c6f
+DIST OpenJDK16U-jdk_x64_linux_hotspot_16.0.2_7.tar.gz 205463525 BLAKE2B 65b8cbf626840e8e3cf5daffda9aed3763ae5c4e2458e71c9854b955cbce8404d498222ec0b30ead9e718d1ee794559f2bcd7b60f630bd0c7e140f671546e873 SHA512 af25ffaeea4034c3d4b14daeacf719e9de87896069885d51c677aaddb3104bc64487fbb4ab33afb420ed88ea60771626f674d998eaed8d4237f1a7cb751c2146
diff --git a/dev-java/openjdk-bin/openjdk-bin-16.0.2_p7.ebuild b/dev-java/openjdk-bin/openjdk-bin-16.0.2_p7.ebuild
new file mode 100644
index 0000000..c2dbbfb
--- /dev/null
+++ b/dev-java/openjdk-bin/openjdk-bin-16.0.2_p7.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit java-vm-2 toolchain-funcs
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk-${MY_PV/+/%2B}/OpenJDK${SLOT}U-jdk_${1}_linux_hotspot_${MY_PV/+/_}.tar.gz
+		)"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JDK binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptopenjdk.net"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~s390"
+IUSE="alsa cups +gentoo-vm headless-awt selinux source"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}"
+
+pkg_pretend() {
+	if [[ "$(tc-is-softfloat)" != "no" ]]; then
+		die "These binaries require a hardfloat system."
+	fi
+}
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED%/}/${dest#/}"
+
+	# Oracle and IcedTea have libjsoundalsa.so depending on
+	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+	if ! use alsa ; then
+		rm -v lib/libjsound.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -v lib/lib*{[jx]awt,splashscreen}* || die
+	fi
+
+	if ! use source ; then
+		rm -v lib/src.zip || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym ../../../../etc/ssl/certs/java/cacerts \
+		"${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+
+	if use gentoo-vm ; then
+		ewarn "WARNING! You have enabled the gentoo-vm USE flag, making this JDK"
+		ewarn "recognised by the system. This will almost certainly break"
+		ewarn "many java ebuilds as they are not ready for openjdk-11"
+	else
+		ewarn "The experimental gentoo-vm USE flag has not been enabled so this JDK"
+		ewarn "will not be recognised by the system. For example, simply calling"
+		ewarn "\"java\" will launch a different JVM. This is necessary until Gentoo"
+		ewarn "fully supports Java 11. This JDK must therefore be invoked using its"
+		ewarn "absolute location under ${EPREFIX}/opt/${P}."
+	fi
+}