Initial commit

5 files changed, 103 insertions, 0 deletions

diff --git a/gui-apps/waypipe/Manifest b/gui-apps/waypipe/Manifest
new file mode 100644
index 0000000..814badb
--- /dev/null
+++ b/gui-apps/waypipe/Manifest
@@ -0,0 +1 @@
+DIST waypipe-v0.6.1.tar.bz2 115292 BLAKE2B 09be6a5a36c5bcf3ceda9a27cdc682e0e3ed18e2c760deed3deb57156d0d1ce35699f098116a5ca31f2b7ea2e6efdc6cfef430b950a4e823a695d533259b9c56 SHA512 86d93c527d08b27d4a29c3e235a7c3399567d771ea462b6a052014a1ef57cae9cdf7a15bb1a4a631ebf664b1c6b36d3b2b50f7f1804302314beb3bb368a12aa4
diff --git a/gui-apps/waypipe/metadata.xml b/gui-apps/waypipe/metadata.xml
new file mode 100644
index 0000000..7395642
--- /dev/null
+++ b/gui-apps/waypipe/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>alex_y_xu@yahoo.ca</email>
+		<name>Alex Xu (Hello71)</name>
+	</maintainer>
+	<use>
+		<flag name="drm">Direct Rendering Manager support</flag>
+		<flag name="man">Install man pages</flag>
+	</use>
+</pkgmetadata>
diff --git a/gui-apps/waypipe/waypipe-0.6.1.ebuild b/gui-apps/waypipe/waypipe-0.6.1.ebuild
new file mode 100644
index 0000000..367f58f
--- /dev/null
+++ b/gui-apps/waypipe/waypipe-0.6.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="proxy for Wayland clients"
+HOMEPAGE="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+SRC_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe/-/archive/v0.6.1/waypipe-v0.6.1.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+drm ffmpeg lz4 +man test vaapi zstd"
+
+REQUIRED_USE="vaapi? ( ffmpeg )"
+
+DEPEND="
+	dev-libs/wayland
+	drm? ( x11-libs/libdrm )
+	ffmpeg? ( virtual/ffmpeg )
+	lz4? ( app-arch/lz4:= )
+	vaapi? ( x11-libs/libva )
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/wayland-protocols
+	man? ( app-text/scdoc )
+	test? ( dev-libs/weston )
+"
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_configure() {
+	local emesonargs=(
+		-Dwerror=false
+		$(meson_feature man man-pages)
+		$(meson_feature ffmpeg with_video)
+		$(meson_feature drm with_dmabuf)
+		$(meson_feature lz4 with_lz4)
+		$(meson_feature zstd with_zstd)
+		$(meson_feature vaapi with_vaapi)
+	)
+	meson_src_configure
+}
diff --git a/gui-apps/wshowkeys/metadata.xml b/gui-apps/wshowkeys/metadata.xml
new file mode 100644
index 0000000..004555a
--- /dev/null
+++ b/gui-apps/wshowkeys/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>alex_y_xu@yahoo.ca</email>
+		<name>Alex Xu (Hello71)</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/gui-apps/wshowkeys/wshowkeys-9999.ebuild b/gui-apps/wshowkeys/wshowkeys-9999.ebuild
new file mode 100644
index 0000000..2d5faf6
--- /dev/null
+++ b/gui-apps/wshowkeys/wshowkeys-9999.ebuild
@@ -0,0 +1,32 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit git-r3 meson
+
+DESCRIPTION="Displays keys being pressed on a Wayland session"
+HOMEPAGE="https://git.sr.ht/~sircmpwn/wshowkeys"
+EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/wshowkeys"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND="
+	dev-libs/libinput
+	dev-libs/wayland
+	virtual/libudev
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+"
+DEPEND="${RDEPEND}
+	dev-libs/wayland-protocols
+"
+
+src_install() {
+	meson_src_install
+	fperms u+s /usr/bin/wshowkeys
+}