1 files changed, 46 insertions, 0 deletions
diff --git a/dev-libs/girara/girara-0.3.6.ebuild b/dev-libs/girara/girara-0.3.6.ebuild
new file mode 100644
index 0000000..712c70f
--- /dev/null
+++ b/dev-libs/girara/girara-0.3.6.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson virtualx
+
+DESCRIPTION="UI library that focuses on simplicity and minimalism"
+HOMEPAGE="https://pwmt.org/projects/girara/"
+
+if [[ ${PV} == *999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://pwmt.org/projects/girara/download/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+fi
+
+LICENSE="ZLIB"
+SLOT="0"
+IUSE="doc libnotify test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-libs/glib:2
+	dev-libs/json-c:=
+	>=x11-libs/gtk+-3.20:3
+	libnotify? ( x11-libs/libnotify )"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )
+	test? ( dev-libs/check )
+	virtual/pkgconfig"
+
+src_configure() {
+	local emesonargs=(
+		-Djson=enabled
+		-Ddocs=$(usex doc enabled disabled)
+		-Dnotify=$(usex libnotify enabled disabled)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}