blob: fb09294beff6d2ae2d089e39dcad6b32f53a2755 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
HOMEPAGE="https://dotnet.microsoft.com/"
LICENSE="MIT"
SRC_URI="
amd64? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-x64.tar.gz )
arm? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-arm.tar.gz )
arm64? ( https://dotnetcli.azureedge.net/dotnet/Runtime/${PV}/dotnet-runtime-${PV}-linux-arm64.tar.gz )
"
SLOT="$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm ~arm64"
IUSE="+dotnet-symlink kerberos lttng"
REQUIRED_USE="elibc_glibc"
QA_PREBUILT="*"
RESTRICT="splitdebug"
RDEPEND="
kerberos? ( app-crypt/mit-krb5:0/0 )
lttng? ( dev-util/lttng-ust:0 )
sys-libs/zlib:0/1
dotnet-symlink? (
!dev-dotnet/dotnet-sdk[dotnet-symlink(+)]
!dev-dotnet/dotnet-sdk-bin[dotnet-symlink(+)]
!dev-dotnet/dotnet-runtime[dotnet-symlink(+)]
)
"
S=${WORKDIR}
delete() {
local x
x=$(find . -name "$1" -print -delete) && [ -n "$x" ]
}
src_compile() {
use kerberos || delete libSystem.Net.Security.Native.so || die
use lttng || delete libcoreclrtraceptprovider.so || die
}
src_install() {
local dest="opt/${PN}-${SLOT}"
dodir "${dest%/*}"
{ mv "${S}" "${ED}/${dest}" && mkdir "${S}" && fperms 0755 "/${dest}"; } || die
if use dotnet-symlink; then
dosym "../../${dest}/dotnet" "/usr/bin/dotnet"
dosym "../../${dest}/dotnet" "/usr/bin/dotnet-${SLOT}"
dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SLOT}"
# set an env-variable for 3rd party tools
echo "DOTNET_ROOT=/${dest}" > "${T}/90${PN}-${SLOT}" || die
doenvd "${T}/90${PN}-${SLOT}"
fi
}
|
